Google Sheets percentage formulas - usage and examples

You may think percentage calculations are useful only if you use them for work. But in reality, they help you in everyday life. Do you know how to tip properly? Is this discount a real deal? How much will you pay with this interest rate? Come find the answers to these and other similar questions in this article.

What is percentage

As you most likely already know, percent (or per cent) means one-hundredth part. It is marked by a special sign: %, and represents a part of the whole.

For example, your and your 4 friends are getting a birthday gift for another friend. It costs $250 and you're chipping in together. What percent of the total you're investing in the present?

This is how you usually calculate percents:

(Part/Total)*100 = Percentage

Let's see: you're giving away $50. 50/250*100 – and you get 20% of the gift cost.

However, Google Sheets makes the task simpler by calculating some parts for you. Below I'll show you those basic formulas that will help you get different results depending on your task, whether calculating percentage change, percentage of the total, etc.

How to calculate percentage in Google Sheets

This is how Google spreadsheet calculates percentage:

Part/Total = Percentage

Unlike the previous formula, this one doesn't multiply anything by 100. And there's a good reason for that. Simply set the format of cells to percent and Google Sheets will do the rest.

So how will this work on your data? Imagine you keep track of ordered and delivered fruits (columns B and C respectively). To calculate the percentage of what's been received, do the following:

  • Enter the below formula to D2:

    =C2/B2

  • Copy it down your table.
  • Go to Format > Number > Percent in Google Sheets menu to apply the percentage view.

Note. You'll need to go over these steps to create any percentage formula in Google Sheets.

Tip. You can decrease and increase decimal places if necessary using the options from the Google toolbar: Adjust decimal places for Google Sheets percentage.

Here's how the result looks on real data: Google Sheets percentage formula.

I removed all decimal places making the formula show the result as a rounded percent.

Percentage of a total in a Google spreadsheet

Here are a few more examples of calculating percentage of a total. Though the previous shows the same, it works great for that example but may not be enough for other data set. Let's see what else Google Sheets offers.

A common table with a total at its end

I believe this is the most common case: you have a table with values in column B. Their total resides at the very end of the data: B8. To find the percentage of the total for each fruit, use the same basic formula as before but with a slight difference – an absolute reference to the cell with the total sum.

This type of reference (absolute, with a dollar sign) doesn't change when you copy the formula to other cells. Thus, each new record will be calculated based on the sum in $B$8:

=B2/$B$8

I also formatted the results as percent and left 2 decimals to display: Calculate percentage of a total.

One item takes a few rows – all rows are part of the total

Now, suppose a fruit appears more than once in your table. What part of the total is composed of all deliveries of that fruit? The SUMIF function will help answer that:

=SUMIF(range, criteria, sum_range) / Total

It will sum only numbers belonging to the fruit of interest and divide the result by the total.

See for yourself: column A contains fruits, column B – orders for each fruit, B8 – the total of all orders. E1 has a drop-down list with all possible fruits where I chose to check the total for Prune. Here's the formula for this case:

=SUMIF(A2:A7,E1,B2:B7)/$B$8 Find the percentage of prune in Google Sheets.

Tip. Having a drop-down with fruits is completely up to you. Instead, you can put the necessary name right to the formula:

=SUMIF(A2:A7,"Prune",B2:B7)/$B$8

Tip. You can also check a part of the total made by different fruits. Just add up a few SUMIF functions and divide their result by the total:

=(SUMIF(A2:A7,"prune",B2:B7)+SUMIF(A2:A7,"durian",B2:B7))/$B$8

Percentage increase and decrease formulas

There's a standard formula you can use to calculate percent change in Google Sheets:

=(B-A)/A

The trick is to figure out which of your values belong to A and to B.

Let's assume you had $50 yesterday. You have saved $20 more and today you have $70. This is 40% more (increase). If, on the contrary, you've spent $20 and have only $30 left, this is 40% less (decrease). This deciphers the formula above and makes it clear which values should be used as A or B:

=(New value – Old value) / Old value

Let's see how this works in Google Sheets now, shall we?

Work out percent change from column to column

I have a list of fruits (column A) and I want to check how prices have shifted in this month (column C) compared to the previous one (columns B). Here's the percent change formula I use in Google Sheets:

=(C2-B2)/B2

Tip. Don't forget to apply the percent format and adjust the number of decimal places.

I also used conditional formatting to highlight cells with percent increase with red and percent decrease with green: Google Sheets percentage formula.

Percent change from row to row

This time, I'm tracking total sales (column B) over each month (column A). To make sure my formula works correctly, I should start entering it from the second row of my table – C3:

=(B3-B2)/B2

Copy the formula over all rows with data, apply the percent format, decide on the number of decimals, and voila: Calculate percentage change in Google Sheets.

Here I also coloured percentage decrease with red.

Percent change compared to one cell

If you take the same sales list and decide to calculate percentage change based on January only, you will have to always refer to the same cell – B2. For that, make the reference to this cell absolute instead of relative so it doesn't change after copying the formula to other cells:

=(B3-$B$2)/$B$2 Percent change based on one cell.

Amount and total by percentage in Google spreadsheets

Now that you've learned how to operate percentages, I hope getting total and the amount will be a child's play.

Find amount when having total and percentage

Let's imagine you've spent $450 shopping abroad and you'd like to have the taxes returned – 20%. So how much exactly should you expect to receive back? How much is 20% of $450? Here's how you should count:

Amount = Total*Percentage

If you put the total to A2 and the percent to B2, the formula for you is:

=A2*B2 Find amount by total and percentage.

Find total if you know amount and percentage

Another example: you've found an ad where a used scooter is being sold for $1,500. The price already includes a pleasant 40% discount. But how much would you need to pay for a new scooter like that? The below formula will do the trick:

Total=Amount/Percentage

As the discount is 40%, it means you are to pay 60% (100% – 40%). With these numbers at hand, you can work out the original price (total):

=A2/C2 Find total by amount and percentage in Google Sheets.

Tip. As Google Sheets stores 60% as one hundredth – 0.6, you can get the same result with these two formulas as well:

=A2/0.6
=A2/60%

Increase and decrease numbers by percentage

The following examples represent the formulas you may need a bit more often than other ones.

Increase a number in a cell by percent

A general formula to calculate the raise by some percent is as follows:

=Amount*(1+%)

If you have some amount in A2 and you need to increase it by 10% in B2, here's your formula:

=A2*(1+B2) Increase the amount by percentage.

Decrease a number in a cell by percent

To make the opposite and decrease the number by a percent, use the same formula as above but replace the plus sign with a minus:

=A2*(1-B2) Decrease the amount by percentage.

Increase and decrease a whole column by percent

Now assume you have lots of records written in a column. You need to raise each of them by a percentage in that same column. There's a quick way (6 steps to be exact) to do that with our Power Tools add-on:

Google Workspace Marketplace badge

  1. Select all values you'd like to raise first and apply the automatic format: Format > Number > Automatic: Apply automatic Number format to your column.

    Note. This is required to avoid problems with formats on the next steps.

  2. Keep the values selected and run the Text tool from Extensions > Power Tools > Tools > Text: Run the Text tool from Power Tools.
  3. Open Add text by position and add an equal sign (=) to add it at the beginning of each cell: Add an equal sign to each cell.
  4. Click Run to turn all your numbers to formulas: Turn all records to formulas by adding a leading equal sign.
  5. Proceed to the Formulas tool in Power Tools and select the option to modify all selected formulas.

    You will see %formula% is already written there. You are to add those calculations you want to apply to all formulas at once.

    Remember the formula to increase a number by percent?

    =Amount*(1+%)

    Well, you already have those amounts in column A – this is your %formula% for the tool. Now you should only add the missing part to calculate the increase: *(1+10%). The whole entry looks like this:

    %formula%*(1+10%) Use the Formulas tool to adjust all formulas.

  6. Hit Run and all records will be raised by 10% at once: Modify all formulas at once to increase all values by 10%.

    Tip. Feel free to apply any number format back to these formulas.


Google Workspace Marketplace badge

That's it! All these examples are easy-to-follow and are intended to remind those of you who've forgotten or show those who don't know the basic rules of calculating percentage in Google Sheets.

Spreadsheet with formula examples

Google Sheets percentage formulas (make yourself a copy to practice)

You may also be interested in

Table of contents

198 comments

  1. Hi

    I'm trying to calculate the following, how can I do it.

    I have a product's cost price, and selling price and would like to know what margin has been put on it, so for example if the cost price is $11.65 and the selling price is $18.95 what is the % profit made here.

    Thanks very much
    Abraham

  2. I am fairly new with google sheets, but I was wondering if it would be possible to track sales over $12 and calculate a 12% tax on those sales? Basically we have a space that is rented to vendors, and any item priced $12 and above would be taxed a 12% fee. We have separate codes for each vender, and I am not entirely sure how we would input this into google sheets. If you could possibly help that would be wonderful! Thank you!

  3. Hi! I'm creating a spreadsheet to track our yearly sales in Real Estate.
    Column B is Commission %, Column C is the Gross Sale Price and Column D is the actual dollar amount of the commission made.

    How would I set something like that up to automatically calculate Column D? Thank you so much!

  4. Hi there,
    What would be the formula for having three columns of data (# of tickets sold today, # of tickets sold yesterday, % of total tickets available sold) and THEN a 4th column for percent increase or decrease from the 3rd column for that day?
    So if our venue has a total of 580 seats and yesterday we were at 120 tickets sold (21%) and today we are at 150 tickets sold (25%), how can I show that ticket sales went up 4%?
    I want to keep the column that shows today's percentage, but also shows how much ticket sales increased/decreased from yesterday.
    Make sense? Thank you!

  5. Thank for the great resource!

    I'm creating a simple budgeting spreadsheet for the wife and me. I can easily reference differences from one sheet to another (Example: (B4-('2021-11'!B4)) , where '2021-11' is the sheet for November 2021 and B4 is the cell I want a differential for).

    Question: Is there a way to make this formula "portable" to auto-reference the sheet before it? I would like to not have to change the sheet name every month when updating.

    Thank you in advance!

    • Thank you for the lovely words, Matt.

      Yes, there's a way. You can incorporate INDIRECT, MONTH and TODAY functions to always subtract 1 from the today's month and reference the sheet for the previous month, like this:
      =B4-INDIRECT("2021-"&(MONTH(TODAY())-1)&"!B4")

  6. do you know how to sort by percentage? like 0.00% to 100.00%?
    thanks

  7. Is there a way I can format a percentage through a formula/function instead of doing it through the formatting toolbar?

    I have this formula and want to make sure the % output is formatted as having two decimal places.
    ex. 1.12% instead of just outputting 1%.

    I have the formatting set to "Automatic" as the same cell is used to output a $ amount depending on the contents of another cell. When the contents of that cell has a certain criterion, a % will show up, which it is doing so correctly, but it's showing up as rounded and i want it to show two decimal places.

    to_percent(A2/A1)

    Thanks
    Jenny

  8. I got this from investopedia.com which says you have to switch numbers in the formula if the price decreases or increases:
    Understanding Percentage Change
    Percentage change can be applied to any quantity that you measure over time. Let's say you are tracking the quoted price of a security. If the price increased, use the formula [(New Price - Old Price)/Old Price] and then multiply that number by 100. If the price decreased, use the formula [(Old Price - New Price)/Old Price] and multiply that number by 100.

    this is totally confusing....

  9. Hello!
    Amazing article that's been super helpful!

    I'm trying to make a tracker on sheets that follow progress of workouts for a group.

    Having to do pull ups, push ups sit ups, etc.. then trying to equal that into a 100%

    Example:
    5 of 15 push ups, 10 of 10 sit ups, and 15 of 15 pull ups = 75%(?) Not great at math...

    Thanks for taking a look at my request for help!

    • Thank you for your feedback, Jon!

      Since I don't know how you arrange your data, I can only hint on the steps to calculate. You'll need:

      1. a total number of repetitions from all sets (15+10+15 = 40)
      2. a total of repetitions actually done (5+10+15 = 30)

      Then you'll be able to find the percentage as described here.

  10. My Rat Turd sized brain still doesn't understand plz help

  11. If I wanted to create a budget spreadsheet, and have Google Sheets calculate the percentages of my check to put away, which one would I use above? So for example, if I want to put in my income as $2000 and have it calculate 70% savings, 20% bills and 10% entertainment for me. Thanks!

  12. Hi,
    I am trying to highlight the cells in column L that DO NOT fall within a certain percentage : between -30% of J2 and +30% of J2

    basically, if value in L2 is NOT within a 30% range (under or over) the value in J2, Then turn the row in RED

    I tried this =and(L2>=0.9*J2,L2>=1.1*J2) in Conditional formatting, but it doesn't seem to be working

    Any help will be greatly appreciated.

  13. can someone help me with this formula ?

    =ARRAY_CONSTRAIN(ARRAYFORMULA(IF($E3:E970*F$1>0, IF($D3:$D970<=EDATE($C3:C970,12),$E3:E970*F$1,""),"")), 968, 1)

  14. i figured it out, sort of lol

    =to_percent((b105:b135-D105:D135)/D105:D135)

    just had to put it in every cell instead of (g) instead of doing a range

    • Hello Mike,

      To check your cells for conditions first (if X sold N last week and N this week), you need to incorporate the IF function. The % increase will be used as a second argument and will happen only if the conditions are true.

      Also, you can calculate this for all rows at once by enfolding the formula in ARRAYFORMULA.

  15. i am trying to figure out a way to make a contest for my employess by amount of sales weekly percentage increase (or decrease)

    i.e. if bob (B105) sold $19876 (D105) last week, and sold 21000 (E105) this week, his % increase would be =X

    is there a way to do this for a whole range... or just line by line?

    as if there were 33 employees, bob being first on 105, and debra being last on 138

    i hope this makes sense?!?!

    thanks in advance!

    • i figured it out, sort of lol

      =to_percent((b105:b135-D105:D135)/D105:D135)

      just had to put it in every cell instead of (g) instead of doing a range

  16. Hello! Thank you for this wonderful resource. I have a chart I need to frequently generate, and am stumped with how to auto populate a certain column. Column A is a date range (fine), Column B is the days within Column A as just numbered 1-->whatever (fine), Column C is data I enter with daily measurements (fine) but the starting number is what controls what I need in Column D and subsequent columns with varying percentage reduction. What I need to figure out is how to take a starting number (call it SN, which begins all the columns I need to auto populate) then take a percentage of that, divide that amount by the number of days in the date range, and subtract sequentially down that column. Example: 3956 SN, take 18% of that (712.08), then divide that amount by 12 days (59.34), each day subtracting another 59.34 while generating a line. The purpose of this is to have a quick, and visual, representation of how daily measurements compare to several ideal percentage reductions, allowing me to adjust the environmental parameters in the project. I am embarrassed to admit I have been doing the calculations and manually entering the results in each cell! This is not good. It's been decades since I've been regularly doing work with spreadsheets and this old brain needs help. Thank you.

    • Nevermind . . . I figured it out! Thanks again for having this site.

  17. I am trying to convert my grades to percents using this form. For example, the sheets generate the score as a number out of the total like: 4/20. How do I get it to create the percentage for each score?

    • Hello Beckie,

      Assuming your total is generated in A2, a formula like this should help:
      =INDEX(SPLIT(A2,"/"),1,1)/INDEX(SPLIT(A2,"/"),1,2)

      Don't forget to apply the Percentage format to your cell with the formula.

  18. Your calculation to find the original price for a 40% discounted scooter is incorrect. Your calculation is 1500/.4 and it should be 1500/.6.

  19. =SOM(B1-A1)/B1 x100
    not working

    4,1 - 3,5 = 0,6 : 3,5 = 0,171x 100 = 17%

    Or :

    3,5 -4,1 = -0,6 : 4,1= -0,146x100=-14,6%

    • Hi Ruud,

      Your formula is written incorrectly:

      1. The function should be SUM, not SOM.
      2. There's no need to SUM if you simply subtract one number from the other.
      3. The multiplication sign in formulas is *, not x.

      Hence, here's how a correct formula should look:
      =(B1-A1)/B1*100

  20. I don't understand

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)