How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. In a specific cell I am wanting it to tell me If a Response is LESS than 28 days old it is Outstanding & If it is MORE than 28 days old it is Overdue (this I can do) BUT I also want it to tell me if another cell on the same sheet contains 'Yes' it overides the previous command and that cell needs to read Complete but if that cell is blank it will ignore the rule. At the minute I have this:- =IF((E3-B7)>28,"Overdue","Outstanding"),IF(M9="Yes","Complete","0")

    • Hi Jen

      Try this one

      =IF(M9="Yes","Complete",IF((E3-B7)>28,"Overdue","Outstanding"))

  2. I want to calculate age between 0-14, 15-24, 25-59 and 70+ from single age registered over the months in input sheet to analysis sheet. I want to know the formula;

    the logic is if a person of 24 age is registered in January, 2014 then it should be counted in 14-24 age group in analysis sheet.

    Thanks

    • You can calculate it using the COUNTIF function.

      Here are the formulas to count age 14 – 24.

      If dates are entered as text, e.g. " January, 2014":
      = COUNTIFS($A$2:$A$100, "<=24", $A$2:$A$100, ">=14", $B$2:$B$100, "January, 2014")

      If the date is formatted like this 1/10/2014, please use this formula:
      =COUNTIFS($A$2:$A$100, "<=24", $A$2:$A$100, ">=14", $B$2:$B$100, "<=1/31/2014", $B$2:$B$100, ">=1/11/2014")

  3. if a1>20 and b1> 50 add a1+b1 if if a1<20 and b1< 50 do nothing

    please i need help on that

  4. A B C D
    1 a:5 b:4 a:26 b:3
    2 a:4 b:45 a:6 b:18
    3 M3 a:50 b:40 a:26 b:30

    how to use IF function on above data. i want to print:

    1) let's say, if the number after the colon [:] equal or more than 5, then just print "a" or "b"
    2)if the number after the colon [:] is less than 5 then print "X".

    • Sorry, I am not sure I can follow you. Can you try to explain in other words?

  5. Hi, Svetlana,

    I'm a bit stuck on finding a formula that will suit my needs. My spreadsheet has column A: first name; column B: last name; column C: type of training; column D: date of training.

    I need a formula that will look at column A, B, and C and if they match any other row in column A, B, and C I need it to select the most recent date.

    this will remove all duplicate training and keep only their most current training record.

    Any suggestions? i'm stumped on this one.

    • If it helps, I can certainly send you a copy of the workbook that I'm trying to do this in.

  6. I have following formula but it writes the result as only A even condition not satisfied

    =IF(F4="","",IF(ISERROR(VLOOKUP($D$4,Sheet5!D:D,4,0)),"A","B"))

    Please Help me

    • Hi Kumar,

      First off, please check the VLOOKUP range. Currently it contains just one column (D) and naturally Excel returns an error. You probably meant:
      VLOOKUP($D$4,Sheet5!D:G,4,0)

  7. hi i am not sure if i will explain it correct but i need help i need a formula to say if c2>d2 then true 3 false 0 and if c2=d2 then true 1 false 0

    thanks very much

  8. I am trying to come up with an IF statement that put a name only if the column to the left of it is not blank. However, there are formulas in the columns to the left that make some of them look blank, even though the actual cell is not blank. What formula can I use to return a blank if the cell has a formula, but is blank?
    I started with this, but I don't know how to exclude the formula.
    =IF(ISBLANK(B8)," ","Clarence")

    • Hi Janna,

      If my understanding of the task is correct, replacing ISBLANK(B8) with B8="" should work a treat:

      =IF(B8=""," ","Clarence")

  9. is there a way to concatenate more than 3 IF functions

  10. i will try my best to explain......let's say we have 1,500 users in c25
    Heading:

    Login's per Month............................Fee
    e25 = 1-1999 ..........................f25 = $10.00
    e26 = 2,000 - 4,999....................f26 = $6.00
    e27 = 5,000 - 9,999....................f27 = $4.00

    if c25 is between 1 and 1999 logins how do we make c28 = f25 or $10.00
    if c25 is between 2,000 and 4,999 logins how do we make c28 = f26 or $6.00
    if c25 is between 5,000 and 9,999 logins how do we make c28 = f27 or $4.00

    We would like to plug the number into c25 and then c28 will change to what ever the fee is.

    thank you soooooooo much

    LC3

    • I think you can concatenate 3 IF functions in this way:

      =IF(AND(C25>=1, C25<=1999), F25, "") &IF(AND(C25>1999, C25<=4999), F26, "") &IF(AND(C25>4999, C25<=9999), F27, "")

      Please note that if a value in cell C28 is outside of 1-9,999 range, the formula will return an empty string.

      • i'm very new at this I preformed a If and put it into cell c28 and got no return, I do put the formula in where I want the change to occur correct?

        • You put the formula in the cell where you want the result to appear.

      • Excellent, THANK YOUUUUUUUUUUUUUU

      • Thank Svetlana... This conversation was a great help for me.

  11. Hi,
    I need to modify the following formula so that when cells B2 or C2 are blank then the output cell is also blank.

    =IF(OR(C2-B2>30,C2>DATEVALUE("12/13/14")),"No","Yes")

    Currently it defaults to "Yes" when they are blank. Can you help me with this? Thank you.

    • Hi Blas,

      Try a nested IF that checks for blanks, like this:

      =IF(OR(C2-B2>30, C2>DATEVALUE("12/13/2014")), "No", IF(AND(B2="",C2=""), "", "Yes"))

      • It worked but I changed the nested IF to OR instead of AND. Thank you very much Svetlana.

  12. I Love You! spot on

  13. Please can you help me with this 1

    If a range of cells (A1:A100) have another cell's data(B1) I want it to return the amount of times that reoccurs into cell C1

    I need to be able to repeat the formula down C column for adding up different data in B1, B2, B3, etc column

    Any Help much appriciated!

    • Column A is lots of different part numbers that repeat sometimes (purchases)
      Column B is the part numbers aranged in numerical order (stock list)and one of each
      Column C is the total of times it was Purchased
      Hope that is clear enough!

      • Hi Andrew,

        I believe the COUNTIF function is better suited for this job. Here's the formula for cell C1, and you can drag it down to other cells in column C:

        =COUNTIF($A$1:$A$100, B1)

  14. Hi TanMan,

    Try this one:

    =IF(A3>6.5, "c", IF(A3<4.5, "a", "b"))

    • Hi, what if I want to do the opposite:

      =IF('Enter Scores'!B7="D", "3",IF('Enter Scores'!B7="B","5.10",IF('Enter Scores'!B7="C","4.50",IF('Enter Scores'!B7="E","1.50",IF('Enter Scores'!B7="F","0",IF('Enter Scores'!B7="A,"6"))))))

      Basically each letter has a number value, if A is entered to B7 on another sheet then the number 6 should show up on the current sheet in the appropriate cell.

      I've added this function to a number of cells and I can't use a =SUM(B6:B12) function because the numbers aren't really 'numbers' according to excel.

      I've formated the cells to recognise the number; but I can't seem to get them to add up; I only get a total of 0.00

      MAybe I need to use another function entirely

  15. looking for some assistance on a formula.

    I have the number 5 in cell a3

    I need in cell b3 if a3 is > 6.5 then I need a letter "c" inputted / if a3 is < 4.5 then I need a letter "a" inputted / and if the a3 is between 4.5 and 6.5 then I need a letter "b" inputted in cell b3

    I tried to do all of this and correcting the errors don't make sense
    any help would be appreciated

  16. Plead help, I need a formula to do the following:
    If A1=Y then both B1 and C1 should either be N or blank, or IF B1=Y then both A1 and C1 should either be N or blank, or IF C1=Y then both A1 and B1 should either be N or blank.
    What I mean is there should only be one Y in any of the cells A1,A2 and A3. Otherwise display error message if there is more than one Y.

    • Hi Ticia,

      The following formula displays "error" if there is more than one Y in any of the cells A1, B1 and C1, it returns an empty string in all other cases.

      =IF(AND(A1="Y", B1<>"Y", C1<>"Y"), "", IF(AND(A1<>"Y", B1="Y", C1<>"Y"), "", IF(AND(A1<>"Y", B1<>"Y", C1="Y"), "", "error")))

      Hopefully this is what you are looking for.

      • Hi Svetlana,

        Thanks for your prompt response. The formula does not seen to work, probably because of where I have placed it. Where can I put the formula to make it work? I placed the formula in data validation -> settings -> allow -> custom -> formula.

        • Ticia,

          Simply copy it into a cell where you want the error message to be displayed.

  17. Can you help me with this:
    IF(D4="DSSM", "B4-210"), IF(D4="DSSM", "B4-180")

    • Hi Rawle,

      I am not sure I fully understand what the formula is supposed to do. If you can explain the conditions to me, I will try to help.

  18. somehow I cannot put does not equal, therefore I will put it in text, in the last bit, the argument is AU19 does not equal zero.

    • Hello Ganaa,

      Try the following IF statement:
      IF(AND('12'!AU190<>"",'12'!AU190<>0),"Required","")

      • Quried

  19. sorry, the last bit looks like this. IF('12'!AU190,"Required","")))

  20. Hello,

    I desperately need help on below case. I am combining two reports, on sheets 12 and 13. With below formula I should be seeing "Required" in the cell because '12'!AU19 is not blank nor zero. Other cells with the same circumstances shows "Required" with no problem. When I evaluate this formula on '12'!AU190 it will actually say that it contains a constant.

    =IF('12'!CQ190,'12'!CQ19,IFERROR(INDEX('13'!$A$1:$ABG$1466,MATCH('Draft (2)'!$A19,'13'!$A:$A,0),MATCH('Draft (2)'!AU$1,'13'!$1:$1,0)),IF('12'!AU190,"Required","")))

    If you could help me on this it would be great. Thank you.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)