How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hi Dear,
    I have 150416060006003 number. Its are come from ERP soft.
    this is dtmsid but i want like this (4/16/2015 8:58:36 PM)
    can you help me

  2. hi,

    I tried this a few times but can't get excel to understand what I need. Is it even possible?

    1 = < 90% 2 = 90% to 97.9% 3 = 98% to 104.9% 4 = 105% to 110% 5 = 110% & above

    I want to get the number 1-5 as results from the percentages value.

    Thanks

  3. IN EXCEL SHEET THERE IS A CELL A1,B1,C1,D1,.....
    IN CELL A1 IS 50
    IN CELL B1 IS 50,
    IN CELL C1 IS A1+B1
    IN CELL D1,IF THERE IS OPTION LIKE YES OR NO,IF I PUT YES IN CELL D1 THE VALUE OF C1 SHOULD SHOW,IF I PUT NO IN CELL D1 THE VALUE OF C1 SHOULD NOT SHOW.
    CELL D1 SHOULD OPERATE CELL C1.
    PLEASE GIVE ME THE FORMULA FOT THIS.

    • Type this in C1:

      =IF(D1="YES",A1+B1,"") -> This way, anything other than "yes" in D1, will not show anything.

      If you want something else to show in case theres neither "yes" or "no" in cell D1, let me know because you'll need a nested IF formula.

      • THANK YOU
        BUT FOR ADDING THIS IS OK, BUT IF I NEED TO MULIPLE OR SUBRACT
        WHAT I SHOULD DO
        FOR EG:IN C1 =A1/50*B1

        WHAT SHOULD I DO

        • SALMAN,

          Just replace A1+B1 in the formula with any other calculation you want, e.g.:

          =IF(D1="YES", A1/50*B1,"")

  4. If I enter cell A1 date C1 should calculate and show number of days pending, if enter date in B1, C1 should show message completed, if A and B1 empty C3 show Don't worry massage.

    • Hi Manju,

      > If I enter cell A1 date C1 should calculate and show number of days pending

      How exactly shall the formula calculate the number of days pending? Is it a difference between the date in A1 and today's date? Shall it be a past or future date, or either?

  5. I need to know the formula if you enter value ex. in cell b2 and the output in b3 will be the date today

    • Put this in B3:

      =IF(B2"",TODAY(),"")

      • For some reason the formula above didnt show up correctly, but between B2 and "" you got to include

        • OMG it isn't showing lol
          you got to include the "not equal" sign

          • THANKS HENRY HELPS A LOT..... :)

    • Henry,

      Our blog engine has problems with < and > symbols, sorry for this.

      Nana,

      Here's the complete formula:
      =IF(B2<>"", TODAY(), "")

      • Thank you! lol

        • THANKS SVETLANA

  6. Hi,

    I need to make cell 'BLANK' if data less than 0.
    I work on daily precipitation data, if precipitation value for day j is missing the value equal to (-999), for this I want cell becomes empty for all the data below zero.
    thank you in advance for any help you provide.

    • You have to open Excel Options, Formulas, and Enable Iterative Calculations.
      then you put in the cell you want to make blank if below zero (for instance A1).

      =IF(A1<0,"",A1)

  7. Hi Svetlana,

    I have cells date formatted to record dates of meetings. Is it possible to have a default text message in each cell 'No Meeting' until a date is entered.

    Otherwise, could I solve this with a drop box which gives a choice of Enter Date or No Meeting. If I use this, is it possible to date format the cell.

  8. Hai Svetlana Cheusheva

    Rupees value
    a1 = no.of student represent
    b1 = no. of students present

    i want the result b1<=5 then value is result 75 (rs) if it is greater than the value b1X10 now i want the formula to get 0 if the value is zero if i want result zero

  9. Hi!

    I am not sure if this IF function can do this in excel, but i'm looking to if the IF function evaluate a column of values for a blank entry, or a null value, then i'd like to output the names of those values in a different sheet.

    Example:

    Supplier Status Paid
    ---------------------------
    Bob Delivered X
    John Delivered
    Mary Delivered X

    I'd like to read the paid column for a blank value, then on another sheet, output all supplier names who haven't been paid. Am I attempting to do something too difficult?

    Thanks for all your help!

  10. I am using excel 2007.
    I have data created every half hour entered in column A starting at 00h 30m
    Column B has nothing in it until 24 hrs has elapsed (00h 00m)then has day "1" displayed in B48.
    C48 has the sum of data for that day only.
    D48 has the sum of data between the hours of 8am and 5pm only.
    Columns B,C, and D have nothing in them until row 48 (end of day).
    I wish to graph the day end results only and my problem is I have 12 months of data in column A.
    My problem is I wish to plot a chart showing the single end of day results only ie just the 365 values in each column every 48 rows down for 17,520 rows (365 days x 48/day).
    How do I avoid plotting the null values in the rows in columns B,C, and D where the intraday data in column A is located. I have been trying to do this by creating another sheet and manually referring to each "day number" row for 365 days and then copying cells sideways but got tired of this after about 12 days. There must be an easier way.
    Can someone please help - I don't know VBA

  11. Hi i want in one raw if value <3 then give me value 0 if <2 then give me 1 and if <1 then give me 2 and if blank give me 3 in one formula so that i can drag same formula in entire excel sheet

    • Hi Dhirendar,

      You can use nested If functions as follows:

      =IF(A1="", 3, IF(A1<1,2, IF(A1<2,1, IF(A1<3,0,""))))

  12. Trying to build a formula where one sheet one there would be a list of colors. On the next sheet would be columns for people to guess a color; however once they guess a color I do not want them to be able to guess that color again. Is there a formula that can compute that.

  13. Trying to build a formula for:
    Row 1 - 200
    Column A measurement
    Column B alpha size.
    I want to show: if A1 is 38<41.5 show s; 42<44 show m; 44.5,47 show l
    Then I can do countif(1:200,"s") etc
    I then want to cross-check:
    count in column A all cells that have measurement 38<41.5

  14. Hi ,

    I am trying to create a formula if the sale days are less than 100 to take the name of the sale item

    • Can you send me a screenshot of it so I have a better idea of how your table is set up?

  15. Hello,
    I am trying to create a formula for:
    CellA: $amount CellB: Store Number
    How can I make all cells with the same store number to add up as the amount is
    being inputted into the table.
    Thank you please help

    • I'm not sure I completely understand your question

  16. ydi mujhe suppose mujhe if condition lagane par coloumn me likhe name chahiye to syntax kya dena hoga

  17. Hello,

    I would like to write a formula to give me alarm by changing the cell to red color and the formula is about the following:
    If the amount in Cell (AE300) is bigger than zero and the date is 30 days before the date in cell (G300), then change the cell (AE300) color into red.

    Thanks in advance.

    • What cell are you taking the first date value from, to compare to the date in G300?

  18. Desired Date: Accomplished date: Result
    15-Nov-15 15-Nov-15 or Lower dates Achieved
    15-Nov-15 16-Nov-15 Failed
    15-Nov-15 Not Accomplish

    Anyone can help? My problem was the blank space; I can’t formulate the blank space. The output was on the right side. Please help me to solve this.

  19. basically i do not want have a value over 1, if it comes out over i want it to be 1. if it is under then whatever the number is fine.

    • =IF((C6/D6)>=1,1,(C6/D6))

  20. I am wanting to put in a formula that I keep getting an error message. This is the basic idea though. IF(C6/d6)>=1,if true = 1, if false use c6/d6. Can somone help me with the formula

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)