How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. pleas upload some educational vedios

  2. Hi there,

    I got the first question solve while I was browsing the above comments, thanks by the way.

    If I may ask again, Could you please help me how to formulate a formula for the following given figures below. I want to calculate the elapsed time in minutes for each row.

    DATE IN TIME IN DATE OUT TIME OUT ELAPSED TIME
    15/03/2015 9:49 15/03/2015 10:30 ?
    15/03/2015 7:00 15/03/2015 13:30 ?
    15/03/2015 8:30 16/03/2015 6:30 ?
    15/03/2015 9:00 22/03/2015 8:30 ?
    15/03/2015 9:30 20/04/2015 6:30 ?

    Many thanks,
    Adzhar

    • lets say A1 = 15/03/2015 10:30 , B1= 15/03/2015 10:30
      then C1 will be : =((B1+0)-(A1+0))*24*60
      the "+0" trick is really cool once you get used to it, it convert values that have diferent types of representations back to its numeric equivalent.
      Next part "*24" turn the value into hours with floating point and the "*60" turn it into minutes.
      If you get strange value just correct the format in C1 and you are good to go :)

  3. Hi Svetlana,

    Good day. I hope you could help me with my issue.

    I want to give a three different ratings for the following figures:

    If 0 to 200 = A
    If 201 to 800 = B
    If greater than 800 and any numbers with a negative signs = C

    Many thanks in advance.

    Regards,
    Adzhar

    • Hi Adzhar,

      Here you go:
      =IF(A1>800, "C", IF(A1>200, "B", IF(A1>=0, "A", "C")))

  4. I have set a couple of conditions as follows

    Permanent 299 0 300 Yes(E7)
    Temporary 3 0 100 Yes(E8)

    Final Result: Yes

    Even if one of the records is failing i.e its a "No" then the final result should be "No"

    For the Final Result I have used the following formulae
    =IF(E7="No","No","Yes")

    My question is how do I define a range (E7 to E8)

    In the above formulae I can only select one particular cell i.e E7

    Regards,
    Sachin

    • Hi Sachin,

      If the range included only two cells, the easiest way is to use the OR statement, like this:

      =IF(OR(E7="No",E8="No"),"No","Yes")

      If the range includes several cells, you can use the COUNTIF function, e.g.:

      =IF(COUNTIF(E7:E16, "yes")=10, "yes", "no")

      Where 10 is the number of cells in the range.

  5. Svetlana,

    Thank you for your continued dedication to this thread and the extremely helpful responses you've given to the users thus far!!
    If possible, I also have a question that you may be able to assist me on.
    I'm utilizing the IF formula as follows:
    =IF(D3=40,"110")
    It goes on continuously basically for a scale that doesn't mathematically progress properly so I'm doing it individually by each number. My question is, when it returns the value of "110", is there a way for Excel to read that as a number and not text? I'm trying to also incorporate a SUM function but it won't read it as an actual number.
    Any insight would be great and thank you again!
    Respectfully,
    Shon

    • Hi Shon,

      This is because Excel interprets any value enclosed in double quotes as a text string. So, simply remove double quotes and your formula will work just fine:
      =IF(D3=40, 110)

      • Svetlana,

        Thank you very much for your insightful assistance and valuable time!

        Respectfully,
        Shon

  6. Hi,

    I am looking for a formula for multiple text. i.e. if bananas, apples and oranges belong to Mr A the result would be Mr A or if potatoes, broccoli and celery the result would be Mr B. Help! Only one column of mixed text with one word per row. Thanks.

  7. I need some help with a formula I am trying to make in a workbook I use for sports tickets. I have a workbook, with a sheet labelled "Cards 2016" that contains all the games with a unique reference of the word “Open” if the tickets haven’t been sold in col E, If col E = “Open” then I want to enter the date from same sheet “Cards 2016” B3 on to a new sheet labelled "Available 2016". If that cell has anything other than "Open", I just want the cell on sheet "Available 2016" to read "Sold"

    This obviously didn't work but here is what I thought would work. In a cell on "Available 2016" I put this formula =IF('Cards 2016'!E5="Open";'Cards 2016'!B5),("Sold")

  8. hai,
    i want a formula stating if A1=B1 "ok" then A1>B1 "short" A1<B1 "excess"
    can you help?

    • Try this:
      =IF(A1=B1,"ok",IF(A1>B1,"short",IF(A1<B1,"excess")))

  9. Hi
    just a correction to the above formula

    =IF(AND(StaffRates!A4=D4,StaffRates!B4""),StaffRates!B4*G4,0)

  10. Hi,

    I am trying to work out staff wages against hours worked. So I have staff names against their rates in a separate worksheet and said names against hours worked I another, so I want to lookup the names then times their respective rates against hours work and populate the earnings column. I am using the following but it only return the zero

    =IF(AND(StaffRates!A4=D4,StaffRates!B4""),StaffRates!B4*G4,0)

    so:
    A4 and D4 holds the names
    B4 is the rates
    G4 hours worked

    Hope this makes sense and thanks for your help.

  11. Hi,
    I see you help many people.

    I would like to compare 2 cells and if the difference is greater than 500, I want it to highlight / put a comment.

    IF(columnA-columnB)>500

    is not working.

  12. Hi,

    I am looking forward to creating one formula excel in which if I enter "1" then it chooses USA, "2" chooses Asia. Can you please tell me how to achieve that.

    Thanks in advance,

    Manaf

    • for Example:
      1 = USA
      2 = INDIA
      3 = UAE
      Regions
      PO Amt Country USA INDIA UAE
      55000 1 55000
      12000 2 12000
      25000 3 25000

    • Use nested IF functions:

      =IF(A1=1,USA,IF(B1=2,ASIA,""))

  13. Help me write function if .for this table below
    Column A1= Mr
    Column B1= " "
    Column C1= " "
    I want result Column D1= Mr

    Column A2= " "
    Column B2= Mrs
    Column C2= " "
    I want result Column D2= Mrs

    Many thank for your help.

    Column A3= " "
    Column B3= " "
    Column C3= Ms
    I want result Column D3= Ms

    • Hi Sem,

      You can use the following nested IF functions:

      =IF(A1<>"", A1, IF(B1<>"", B1, IF(C1<>"", C1, "")))

  14. Dear
    i am working shift A B C D,MORNING,AFTERNOON,NIGHT AND SHIFT OFF FOR EXPL

    SHIFT-1 A A M M N N O O

    SHIFT-2 M M N N O O A A

    SHIFT-3 O O A A M M N N

    SHIFT-4 N N O O A A M M

    ALREADY ARRANGE AUTOMATIC YEARLY CALENDAR BUY I CAN'T LINK WITH SHIFT

    HOW CAN I DO THIS PL TELL ME
    THANK YOU

  15. Can someone help me to build an excel formula that will return a list of drivers who have driven over 5,000 miles? Column A lists drivers' names, columns B-P list how many miles each driver has driven on different trips. Column Q totals those columns; "total miles" for each driver. Column R has the IF function that basically states, if the total miles in Column Q exceeds 5,000, return the name of that driver. Here is the formula; =IF(Q2>5000, A2, " "). It works, but I get a list of names with blank cells in between. I just want list of the drivers who have exceeded 5,000 without the blank cells in between (the blank cells are the drivers who have not exceeded 5,000 miles. So if my boss were to ask me, "Get me a report of all the drivers who have exceeded 5,000 miles", I don't want to hand him a spreadsheet that has a name, then a couple of blank cells, then a name, and a few more blank cells, etc. Thank you for your help.

  16. Please help me to create booking number for below case:

    if I add company name i need new booking number for this company.

    Exaple-

    Company Name | Booking Number
    A 211
    A 212
    B 101
    C 456
    A 213
    C 102

    Thank you in advance

  17. Hello,
    I am trying to use an if function and have the following:
    =IF(H6="E6/7","","Reset Required")

    However, I haven't been able to figure out how to have the cell return to and empty cell instead of it coming up "reset required" when items in column H are blank? Can you help me?

    • Hi Rachel,

      Just add one more condition to your formula, like this:
      =IF(OR(H6="E6/7", H6=""), "","Reset Required")

      FYI, if E6 in your formula is a cell reference, then you shouldn't enclose E6/7 in double quotes, otherwise Excel interprets it as a text string.

  18. HI , I am trying to do an if statement bringing information from sheets labeled Jan, Feb, Marc, etc. I want the same information every month.I have a sheet with the totals on same excel sheet as the months, that I want to transfer my info monthly too. right now the formula that the person before me has reads like this
    {=SUM(IF(June!M:M="IC",1,0))}
    so from the calls we get it they are an IC (incoming call) OC (outgoing call) etc I want them to return a number. I hope this makes sense. I have not been able to duplicate this formula. when I entere the formula in it does not calculate it just stays as this
    {=SUM(IF(August!N:N="IC",1,0))} What am I doing wrong.

  19. Hi,

    I'm trying to generate a formula that will list a "last completed" date (from column E) for each of the categories in column A.

    =MAX(IF(A3:A100=$I$2,E3:E1000=DATEVALUE("mm/dd/yyyy")))

    Column A: Column E: Column H: Column I:
    1 [title]
    2 Children's DVDs 7/13/2015 Adult fiction books
    3 Adult Biographies 10/7/2015 Last Completed:[formula here]
    4 Adult Fiction Books 11/18/2015
    5 Adult Fiction Books 12/12/2015
    6 Adult Biographies 12/13/2015
    7 Children's DVDs 12/19/2015 ...

    I'm not very good with multiple criteria formulas, so I know something is off.

    Thanks!

    • oh, the spacing got screwed up.The titles are under column A (Children's DVDs etc.) The Dates are under column E. Column H has the "last completed" and Column I has the actual formula. Sorry.

  20. Hello Svetlana!
    I want to create a formula in order to calculate Personal Income Tax.
    If gross amount equal or less than 2500 we should subtract 136 (tax relief) from taxable gross amount then find 14% of the gross. If gross amount is equal or less than 136 (0-136) we shouldn't pay any amount.
    Gross amount Tax
    2500 ?
    160 ?
    This is my old formula
    =IF(B13<=2500;B13*0,14;(B13-2500)*0,25+350)
    Could you please help me?

    Merry Christmas and Happy New Year!
    Thanks in advance

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)