How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hi Svetlana Cheusheva
    i need some help with one formula.
    i need a formula if i have in cell A1 text "UP" or "OA" or a value <80 to result/display 30 and in the same cell A1 if i have text "STD" or a value <100 to result/display 45
    thank in advance
    Mihai

    • Hello MIHAI,

      Here you go:

      =IF(OR(A1="UP", A1="OA", A1<80), 30, IF(OR(A1="STD", A1<100), 45, ""))

  2. I am unable to paste the exact command here as there seems to be a problem in your website.
    Basically if the value in B24 is 0-20, it should be excellent, if it is 20-50, it should be OK, If it is 50-100, it should be subjective, If it is greater than 100, it should be "Over Subjective".

  3. =IF(AND(B24>=0,B24=21,B24=51,B24100,"Over subjectivity"))))

  4. Hi please tell me what am i doing wrong, as whatever value less than 100 in B24 cell is entered. It always gives "Excellent Rating". Basically i am working on automated rating system on daily performance.
    =IF(AND(B24>=0,B24=21,B24=51,B24100,"Over subjectivity"))))

  5. Hi, can you please help me??
    i want to apply "if formula" in below type of scenario.
    if A2 & B2 = BLANK THEN "..." otherwise "...." then again i want to add formula in same formula like a2=blank & b2=not blank then "..." otherwise "..."

  6. Hi, need a formula that will look for numbers either in cells A2 or B2 and if present add the total of A2 and B2 to the number in N1 and show in N2.

    Thank you for your help.

    • Hi Legat,

      Here is a formula for N2:

      =IF(OR(A2<>"", B2<>""), A2+B2+N1, "")

  7. Hello,

    I want to give If formula,

    in Perticular Cell if 4 result should be 1, if 8 result 2, like that multiple ive to get. Please assist me on this.

    • Hello GANESH,

      You can use the following nested IF's:

      =IF(A1=4, 1, IF(A1=8, 2, ""))

  8. Hi Svetlana,
    Is there a shorter way to do this?

    =IF(R4>=30,0,IF(R4=29,1,IF(R4=28,2,IF(R4=27,3,IF(R4=26,4,IF(R4=25,5,IF(R4=24,6,IF(R4=23,7,IF(R4=22,8,IF(R4=21,9,IF(R4=20,10,IF(R4=19,11,IF(R4=18,12,IF(R4=17,12,IF(R4=16,12,IF(R4=16,12,IF(R4=15,12,IF(R4=14,12,IF(R4=13,12,IF(R4=12,12,IF(R4=11,12,IF(R4=10,12,IF(R4=9,12,IF(R4=8,12,IF(R4=7,12,IF(R4=6,12,IF(R4=5,12,IF(R4=4,12,IF(R4=3,12,IF(R4=2,12,IF(R4=1,12,IF(R4=0,12))))))))))))))))))))))))))))))))

  9. Hi Svetlana
    For question 790 is this correct:
    =IF(R4>=30,R4+T4-V4,IF(R4<=29,MIN(R4+T4-V4,30)))

  10. Hi, can you help me with this please?

    =IF('6'!$K$8>0, '6'!$K$4, "")

    So what I want to achieve is: if K8 in tab 6 is greater than 0, it will show the value in K4 in tab 6, if not blank.

    However it is not working, it doesn't take into consideration whether K8>0 or not, it just shows the value in K4 anyway.

    Thank you and I appreciate your help!

    • nvm I got it thank you

  11. Hi Svetlana,
    Hope you can help me as I can't find the answer anywhere. Our challenge is for our sick days calendar. We created a spread sheet with 5 tabs from 2016 to 2020. We have changed our system so you can collect only 30 sick days. Some people who have been employed for a long time have more then that and they are allowed to keep adding to their days. So my claculation needs to be if over 30 days keep adding, if they fall under the 30 days in a calendar year they can collect no more then 30 days. Below is my formula for not over 30 but how do I do the first part?
    =MIN(C14+E14-G14,30)

    Thanks

    • Is this correct>
      =IF(R4>=30,R4+T4-V4,IF(R4=30,0,IF(R4=29,1,IF(R4=28,2,IF(R4=27,3,IF(R4=26,4,IF(R4=25,5,IF(R4=24,6,IF(R4=23,7,IF(R4=22,8,IF(R4=21,9,IF(R4=20,10,IF(R4=19,11,IF(R4=18,12,IF(R4=17,12,IF(R4=16,12,IF(R4=16,12,IF(R4=15,12,IF(R4=14,12,IF(R4=13,12,IF(R4=12,12,IF(R4=11,12,IF(R4=10,12,IF(R4=9,12,IF(R4=8,12,IF(R4=7,12,IF(R4=6,12,IF(R4=5,12,IF(R4=4,12,IF(R4=3,12,IF(R4=2,12,IF(R4=1,12,IF(R4=0,12))))))))))))))))))))))))))))))))

  12. Hope you can help...I'm struggling with this!
    I need the result of cell F12 to be this: If E12 is less than 40 then cell F12 is equal to E12 BUT if E12 is greater than 40 then F12 is equal to E12-40.
    i hope that makes sense!
    Thanks

  13. So here is my problem:
    =if(E4=L5,G4=M5)
    WHY IS THIS NOT WORKING?
    So what I am really trying to do is I have a chart and on this chart I have 10 - 100 going by 10's so 10 goes with 133, 20 goes with 263, 30 goes with 407...
    so I need to set up a data base where is someone is a 10 another cell automatically shows 133.

    • Hi,

      I am not sure I can follow you regrading the chart. As for your formula, you can enter this one in cell G4:
      =IF(E4=L5,M5)

  14. Hi Svetlana,

    Could you please help with the following issue.
    I need to set a formula for cashflow model. Let say in cell A2 i show cash needed to raise, which depends on cell A1 (net cash), so whenever A1 is negative A2 should show amount needed to raise, however A2 also depends on how much money we have in reserve (acummulated) in A3.So i cannot simply use =if(A1<0;-A1;0), because it is possible that i already have some accumulated cash in reserve from previous months and do not need to raise money from external sourse. So the formula needs to take enough money from reserve and show the rest which is needed to be raised.
    I hope my explanation is understandable.

  15. How would I enter:

    if cell A is greater than number Y but less than number Z put a 1, otherwise return a blank space?

  16. I need a formula for grades in a spreadsheet. If the reading (G), Math (M), or Science (S) grade is less than 70, the student is "At Risk". Otherwise, the student is "Low Risk". What do I need to change in this formula?

    =IF(OR($G5<70, $M5<70, $S5<70), "At Risk", "Low Risk")

  17. Hi, need help with a formula
    I need to add P3+R3-T3 into X3 if that number is over 30, i need to display that number, if that number is under 30 I need it to display that number but not go over 30

  18. =IF(C6="","",VLOOKUP(C6,C6:D6,2,0)),IF(C1="A","2%",IF(C1="B","2%"))

    please help function not working

    • note that "" and blank are not the same
      if C6 is formula then it should be working, if not then

      IF(isblank(C6),"",VLOOKUP(C6,C6:D6,2,0)),IF(C1="A","2%",IF(C1="B","2%"))

  19. is there a way to have the data auto fill from A4 into Cell A3 If the data in A1 matches A2?

    • Hi Venessa,

      You can enter the following formula in A3:

      =IF(A1=A2, A4, "")

  20. Hi Svetlana,

    Good day. I hope you could help me with my issue.
    If 6 or 12 30%discount, if not 0%

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)