How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Pleas help me what formula should i have to use. If cell
    A1=1 the answer should D1, then
    A1=2 the answer should D2, then
    A1=3 the answer should D3, then
    A1=4 the answer should D4, and so on.

    hoping for you quick answer.

    Many thanks.

  2. Hi Svetlana,,

    Thanks for the solutions you've shared. I found them very helpful, though I am not that 100% sure that I can get them right. I haven't tried yet some of them, and to what my concern is, I didn't find a solution to my problem still despite of all the shared solutions. Could you please direct me to a certain solution to my case?

    My question was, how may I convert a given sample/answer (ex: 3days 10hours 35minutes) in a certain cell into a total minutes only (ex: 382719)?

    In other words I just want to simply convert them into total minutes using 1 formula with the given sample above as: 3days 10hours 35minutes

    Many thanks,

    Adzhar
    Reply

  3. if the cell has a vlue it has to take that value or else it has to take next cell value by multiplying *3.75
    Ex-if A1 has a vlue it has to take A1 or else it has to B1*3.75
    Anybody can help to solve this function

      • Thank you Svetlana ..Thanks alot it is very help to my day today work..once again thank you...

  4. I have one table that has a Zip code and other info about a person and also needs a County column filled in this same table. I have another table that has Zip Code with a County connected to it. How would I approach this?

    • table 1 that needs the county info attached has the following columns.. Zip is H. Where I need the data is N. The other table where im pulling the county info from is.. Zip is column T and county column V

  5. Hello,

    I have an Excel spreadsheet where multiple people update frequently. I want column L to automatically update with the date when column J (status) was updated with any text information. Can I use If formula, and if so, how do I write it?

  6. Hi there,

    good day. I am trying to make a date to a number (the month to be number 1,2,or 3), but I don't know how to set the formular, could you please help?

    example:

    2/Jan/16 = 1
    3/Mar/16 = 3
    5/Apr/16 = 4

    Thank you very much in advance for your kind help. Looking forward to hear from you. have a great day.

      • Hi Svetlana Cheusheva,

        Thank very much, wish you have a pleasant day :)

  7. Hi,

    I have a customer list in excel, and am trying to mark each customer as either 'new' or 'repeat'. A new customer is one that appears only once in the list, and a repeat customer appears in the list more than once.

    Can you help with this? Thank you so much.

    • Hi Mick,

      You can use a formula similar to this, where column A is customer names:

      =IF(A1="", "", IF(COUNTIF(A:A, A1)=1, "new", "repeat"))

  8. Why is this not working?

    =if(G1="",E1,G1)

    However, when G1 is blank "", it is not giving me the value of E1, it is just showing a blank cell?

    When G1 contains a value, it gives me the value of G1

    Am I overthinking this?

    • Hi!

      Your formula is all right, and you can make sure of this by testing it on a new sheet. Most likely there's some issue with your source data, but it's not possible to pin down the root of the problem without seeing it.

  9. hi,
    I have 4 excel sheets and work done in all sheets is of same kind, i work on particular numbers. so i want a formula by which i can know while working in any sheet that on this number you have already worked whether by coloring that number or highlighting or by any way. can anyone here hlp?

  10. Hi Svetlana,

    Good Day, I am working on two different cells, one cell has 4 categories(james,nadine,clark,leah) while the other cell has 3 options (yes, no, NA). Per category has different values, let say for james, the value of (yes, no, na = 20, 0, na), whilst, nadine has (10, 0, na). This is my formula but it doesn't seem to work:( I know there is too many conditions. I do not know how to simplify it. Thanks in advance and more power.

    =IF(C104="james",IF(D102="yes",10,IF(D102="no",0,IF(D102="NA",D102)))):IF(C104="nadine",IF(D102="yes",20,IF(D102="no",0,IF(D102="NA",D102))))

    • Hello, Mitch,

      Could you clarify what result you need to get? If no is selected for James, what needs to be displayed in the resulting cell? Thank you.

      • Mitch,

        Please try this formula:

        =IF(D102 = "NA", "na", IF(D102 = "no", 0, IF(C104 = "nadine", 10, IF(C104 = "james", 20, IF(C104 = "clark", 30, IF(C104 = "leah", 40))))))

        Please modify the values for clark and leah according to your data.

  11. % time exceed ranges from +51% and above 1
    % time exceed ranges from 1% to +50% 2
    % time exceed ranges from 0% to -24% 3
    % time exceed ranges from -25% to -50% 4
    % time exceed ranges from -51% and below 5

    • can you help me write a formula with these. if like for example cell a1 reach value of +51% and above it gets the value of 1, so on.

  12. Hi, how can i formulate the value of YES to 4 and NO to 0? Meaning, all YES are equal to 4 and NO is 0.

    Thanks

    • Hi Mervin,

      If you want to input 4 or 0 in some column depending on the value in another column (column A in this example) in the same row, you can use the following formula:

      =IF(A1="YES", 4, IF(A1="NO", 0, ""))

      If you want something different, please clarify.

  13. I am trying to formulate an spreadsheet to determine employee vestment. I need a formula that shows if the date in C2 is two or more years from the current date then D2 will show YES but if it's less than two years from the current date D2 will show NO.

    • Hello Tiffany,

      Does "the date in C2 is two or more years from the current date" mean 2 or more years in the past or in the future?

      If C2 is a past date, you can use the following formulas:

      To calculate the difference in complete calendar years, use the DATEDIF function:

      =IF(DATEDIF(C2, TODAY(),"y")>=2, "YES", "NO")

      To calculate the difference by subtracting the year in C2 from the current year, use this formula:

      =IF(YEAR(TODAY()) - YEAR(C2)>=2, "YES", "NO")

      If C2 is a future day, you just need to swap today() and C2 in both formulas.

  14. Sorry, i pressed enter before i could finish.

    Table 2

    Year Period Date
    2012 1 01/01/2012
    2012 3 03/01/2012

    I would like to put a date in table 1 under the ? column if the two condition of the year and period are meet corresponding to table 2.

    I hope that makes since. I have been trying to use a IF formula, but to no luck. Am I missing something.

    Thank you.

  15. Can i use a IF formula to perform the following.
    Table 1
    Year Period ?
    2012 3

    Table 2
    Year Period Date
    2012 1

  16. I have a spread sheet for some frequency assessments for the testing of equipment. There are several boxes at the beginning of the assessment sheet where I add in a number and a box at the bottom which gives me a overall score, from all the upper boxes being added together.
    I want to put another box next to overall score box, that will be auto-populated with text and that text will be dependant on what the score is.
    E.g - If score is between 1 - 14, then the box should show the text "3 Yearly".
    15 - 29 = "2 Yearly"
    30 - 44 = "Yearly"
    45 - 60 = "6 Monthly" and
    61 - 75 = "3 Monthly"

    Tried several IF formula, but nothing working.

    Many thanks

    • Hi Dave,

      You can use the following nested If functions:

      =IF(A1>60, "3 Monthly", IF(A1>44, "6 Monthly", IF(A1>29, "Yearly", IF(A1>14, "2 Yearly", IF(A1>0, "3 Yearly", "")))))

  17. Hello Svetlana,

    I need a Formula with possible 4 options:
    If A1="yes" and B1="yes" then use value(€)C4 in field D1
    If A1="no" and B1="yes" then use value(€)C3 in field D1
    If A1="yes" and B1="no" then use value(€)C2 in field D1
    If A1="no" and B1="no" then use value(€)C1 in field D1

    Is it possible to help me out?

    Kind regards,
    Patrick

    • Hello Patrick,

      Here's the formula for D1:

      =IF(AND(A1="yes",B1="yes"), C4, IF(AND(A1="no",B1="yes"), C3, IF(AND(A1="yes",B1="no"), C2, IF(AND(A1="no",B1="no"), C1,""))))

      • Hey Svetlana,

        This is the final formula for D1:

        =IF(AND(A1="ja";B1="ja");C4;IF(AND(A1="nee";B1="ja");C3;IF(AND(A1="ja";B1="nee");C2;IF(AND(A1="nee";B1="nee");C1;""))))

        It won't work with "," only with ";" in the formula.
        That's why I couldn't figure out what was wrong earlier...
        Does it got anything to do with the version (2013) of excel?

        Thanks for your help anyway!

        Kind regards

        • Hi Patrick,

          >Does it got anything to do with the version (2013) of excel?

          Nope, it depends on what character is set as the List Separator in your Regional Settings (Control Panel > Region and Language > Additional Settings).

          Usually comma is the default list separator in North America and some other countries. On my PC it is also the comma and that is why I separated the arguments with ",".

          In European countries, comma is used as the decimal symbol and the list separator is usually set to a semicolon, which seems to be your case.

          • All clear.

            Thanks again!

  18. Hi Svetlana,

    Good day.
    One more help please.

    Could you help me, convert (ex: "3days 1hour 25minutes") into minutes. Just to "total minutes" only, so that I can have them rate easily.

    Many thanks in advance.

    Adzhar

  19. Hi ,

    i Want to find out rankin 100 above 1 and 50 above but less 100 2 and below 50 shown 3,

    CAE Name TARGET ACHIVEMANT RANKING
    GAD GAD %SSO 55%
    Sanjay 1300 1101 85
    Vikas Tiwari 1200 849 71
    Neeraj Tiwari 250 243 97
    Sambhunath 300 236 79
    Virendra kumar 600 621 104
    Kamlesh 200 244 122
    Shailendra 450 551 122
    Ravi 450 395 88
    Sreesh mishra 200 332 166

  20. I am trying to get the following:
    in Cell AV756 i have the following string:
    =IF(OR(AB756="Bid",Y756>0),Y756,""),IF(OR(AB756="Bid",AA756>0),AA756,"")

    If Cell AB756 has the word Bid and If Cell Y756 has a Value return that value in AV756 otherwise leave blank
    If Cell AB756 has the word Bid and If Cell AA756 has a value return that value in AV756 otherwise leave blank

    I am trying to get thee value from either Y756 or AA756 to populate Cell AV756 if AB756 has the word Bid, only one of the Value cells Y756/AA756 will have a value at any one time.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)