How to use IF function in Excel: examples for text, numbers, dates, blanks

In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

Logical_test (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

Value_if_true (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the value_if_false argument must be defined.

Value_if_false (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the value_if_true argument must be set.

Basic IF formula in Excel

To create a simple If then statement in Excel, this is what you need to do:

  • For logical_test, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators.
  • For value_if_true, specify what to return when the logical test evaluates to TRUE.
  • For value_if_false, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

=IF(B2>80, "Good", "Bad")

This formula goes to C2, and then is copied down through C7: Basic IF formula in Excel.

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

=IF(B2>80, "Good", "")

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise: IF formula to return nothing when the condition is not met.

Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

If value_if_true is omitted

If the 2nd argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

=IF(B2>80, , "Bad")

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

=IF(B2>80, "", "Bad")

The screenshot below demonstrates the difference: The behavior of the value_if_true argument.

If value_if_false is omitted

Omitting the 3rd parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after value_if_true, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

=IF(B2>80, "Good")

Typing a comma after the value_if_true argument will force Excel to return 0, which doesn't make much sense either:

=IF(B2>80, "Good",)

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

=IF(B2>80, "Good", "") The behavior of the value_if_false argument.

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for value_if_true and FALSE for value_if_false. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use If then statements in real-life scenarios.

Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

  • Equal to (=)
  • Not equal to (<>)
  • Greater than (>)
  • Greater than or equal to (>=)
  • Less than (<)
  • Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a negative number:

=IF(B2<0, "Invalid", "")

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell. A formula to check if a cell contains a negative number.

Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the Delivery Status in B2 to determine whether an action is required or not:

=IF(B2="delivered", "No", "Yes")

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise. Using the IF function with text.

Another way to achieve the same result is to use the "not equal to" operator and swap the value_if_true and value_if_false values:

=IF(C2<>"delivered", "Yes", "No")

Notes:

  • When using text values for IF's parameters, remember to always enclose them in double quotes.
  • Like most other Excel functions, IF is case-insensitive by default. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

=IF(EXACT(B2,"DELIVERED"), "No", "Yes") Case-sensitive IF statement for text values.

If cell contains partial text

In situation when you want to base the condition on partial match rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes") IF cell contains partial text.

For more information, please see:

Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date. Excel IF statement with dates.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

=IF(B2>$E$2, "Coming soon", "Completed")

To compare a date with the current date, use the TODAY() function. For example:

=IF(B2>TODAY(), "Coming soon", "Completed")

Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

  • Use the IF function together with ISBLANK, or
  • Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

  Logical test Description Formula Example
Blank cells =""

Evaluates to TRUE if a cell is visually empty, even if it contains a zero-length string.

Otherwise, evaluates to FALSE.

 =IF(A1="", 0, 1)

Returns 0 if A1 is visually blank. Otherwise returns 1.

If A1 contains an empty string (""), the formula returns 0.
ISBLANK()

Evaluates to TRUE is a cell contains absolutely nothing - no formula, no spaces, no empty strings.

Otherwise, evaluates to FALSE.

 =IF(ISBLANK(A1), 0, 1)

Returns 0 if A1 is absolutely empty, 1 otherwise.

If A1 contains an empty string (""), the formula returns 1.
Non-blank cells <>"" Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered blank.

 =IF(A1<>"", 1, 0)

Returns 1 if A1 is non-blank; 0 otherwise.

If A1 contains an empty string, the formula returns 0.
ISBLANK()=FALSE Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE.

Cells with zero-length strings are considered non-blank.

 =IF(ISBLANK(A1)=FALSE, 0, 1)

Works the same as the above formula, but returns 1 if A1 contains an empty string.

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

=IF(B2="", "", "Completed")

=IF(ISBLANK(B2), "", "Completed")

=IF($B2<>"", "Completed", "")

=IF(ISBLANK($B2)=FALSE, "Completed", "")

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results: IF statement for blank and non-blank cells.

Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

=IF(B2=C2, "Same score", "") Check if two cells contain the same values.

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

=IF(EXACT(A2, B2), "Match", "Don't match") Case-sensitive IF formula to check if two cells match.

IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the value_if_true and/or value_if_false arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

=IF(B2>80, B2*7%, B2*3%) IF formula that runs another formula.

Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

  • Nesting several IF functions one into another
  • Using the AND or OR function in the logical test

Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

  • Over 90 - 10%
  • 90 to 81 - 7%
  • 80 to 70 - 5%
  • Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%))) Nested IF statement.

For more formula examples, please see:

Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

=IF(AND(B2>80, C2>80), "Pass", "Fail")

To get "Pass" if either score is higher than 80, the formula is:

=IF(OR(B2>80, C2>80), "Pass", "Fail") Excel IF statement with multiple conditions.

For full details, please visit:

If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" ) If error formula in Excel.

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

Practice workbook

Excel IF statement - formula examples (.xlsx file)

Table of contents

4804 comments

  1. Hi,
    I have one question.
    Actually i just want to create a new cell if my "if Condition" become true and not to create any cell if condition become false.
    Can you please suggest is there any way to resolve with this issue ?

    Thanks in advance.

    • You may have to learn VBA for this.

  2. Hi,

    Is there an 'If Statement' formula for a pie chart that will say ...
    'If A4 = 0 dont include, if A4 = >1 include' ??

    Thanks

  3. B6 is 70% And D19 is 0 i need the result is Needs Improvement.

    Now I'm Trying with this one which is not getting the result.

    IF(AND(B6>=70%,D19=0,"Needs improvement".

    Please help me.

    • =IF(AND(B6>=70%,D19=0),"Needs improvement","")

  4. B6 is >70% And D19 is 0 i need the result is Needs Improvement.

    Now I'm Trying with this one which is not getting the result.

    IF(AND(B6>=70%,D19=0,"Needs improvement".

    Please help me.

  5. Hi,

    I would like to create a formula for a spreadsheet.

    If D4 = 1, then F4 = $15
    If D4 = 2, then F4 = $20
    If D4 = 3, then F4 = $25
    If D4 = 4, then F4 = $30
    If D4 = 5, then F4 = $35
    If D4 = 6, then F4 = $40

    etc.. all the way to D4=10, then F4=$60 ($5 increments).

    Essentially, all I would like to do is enter the number '5' into D4 and the appropriate total cost will automatically appear in F4.

    Thanks in advance!

    • Hi,
      Type this into F4,

      =D4*5+10

      And format it as currency ($)

      Using If loops make it messy. If you must use If, use the following,
      =IF(D4=10,60,IF(D4=9,55,IF(D4=8,50,IF(D4=7,45,IF(D4=6,40,IF(D4=5,35,IF(D4=4,30,IF(D4=3,25,IF(D4=2,20,IF(D4=1,15,"Enter a correct value"))))))))))

  6. Kindly prepare a formula or correct this formula

    If a man bought x, he is entitled for 0.8*the price
    If a man bought y, he is entitled for 0.8*the price if 0.8 *the price < 100 otherwise he will be paid 100

    If a man bought z, he is entitled for 0.8*the price if 0.8 *the price < 1500 otherwise he will be paid 1500

    =+IF(G2=0,0.8*L2,(IF(AND(G2=1,L2*0.8<100),0.8*L2,100,(IF(AND((G2=2),(L2*0.8<1500)),0.8*L2,1500,(IF(G2=3,L2,L2)))))))

  7. I would like to create a formula by if

    check value of a cell A2 = 1,
    if true its will select a already written value from a cell H2,
    if false we wants go for another checking A2 = 2,
    if second checking is true its will select a already written value from a cell H2,
    if second checking is false we wants go for another checking A2 = 3
    if Third checking is true its will select a already written value from a cell H3
    if Third checking is false we wants go for another checking A2 = 4

    its will a continuous checking in each cell. is it possible in excel by "IF" function ?

  8. Hi,
    I would like to create an "if and" formula where: if the value in h183 is 4 and the value in a183 is 1, then the value in i183 is 2. It seems simple but I can not get the syntax correct. I have tried
    =if(AND(H183=4,A183=1)),[I183=2]
    what am I doing incorrectly.
    Thank you

    • Hi!

      You were almost there :)

      Try to enter the following formula in I183:

      =IF(AND(H183=4,A183=1), 2, "")

  9. i want to know formulae for example that DHL, FEDEX, ARAMAX HAS DIFFERENT FUEL SURCHARGE LIKE 14.50%, 15.50% AND 13.50%....SO HOW CAN WE FILL ONE CELL FEDEX AND GET VALUE ON ANOTHER CELL 15.50%

    PLS HELP ME

  10. What will be the formula of if for multiple reason. Such as from USD 0 to 200,000 tax will be 1%, 200,001 to 500,000 will be 2.5%, 500,001 to 1500,000 will be 3.5%.

  11. How does one combine the 4 IF Formula in one cell? I'm able to combine 2 together with no issues but when trying to combine 3 or all its fails.

    1. If A1 is blank (True) then D1 is blank
    =IF(ISBLANK(A2)=TRUE,””)

    2. If A1 is not blank and B1 and C1is blank then D1 = A
    =IF(ISBLANK(A8)=FALSE,IF(ISBLANK(B8)=TRUE,IF(ISBLANK(C8)=TRUE,"A")))

    3. If A1 is not blank and B1 is not blank and C1 is Blank (True) then D14 = B
    =IF(ISBLANK(A14)=FALSE,IF(ISBLANK(B14)=FALSE,IF(ISBLANK(C14)=TRUE,"B")))

    4. If A1 is not blank (False) and B1 is blank (True) and C1 (False) is not blank then D19 = C
    =IF(ISBLANK(A19)=FALSE,IF(ISBLANK(B19)=TRUE,IF(ISBLANK(C19)=FALSE,"C")))

    Formula 1 and 2 together.
    =IF(ISBLANK(A1)=TRUE,"",IF(ISBLANK(A1)=FALSE,IF(ISBLANK(B1)=TRUE,IF(ISBLANK(C1)=TRUE,"A"))))

    • Hi TinWin,

      Try the following formula:

      =IF(ISBLANK(A2), "", IF(AND(ISBLANK(B2), ISBLANK(C2)), "A", IF(ISBLANK(C2), "B", IF(ISBLANK(B2),"C"))))

      • Wow you rock Svetlana! That totally worked!

  12. I having trouble getting a if statement to perform a formula if the condition applies but to do nothing if it doesn't.
    here is my sample
    I need the number of characters in a cell to be 20 or less, so I want to reduce the number using this formula =IF(LEN(A1>=20),LEFT(A1,LEN(A1)-10))
    which works just fine, but i want it to do just copy the value in the the original cell if the length is already less than 20.
    What do i have to add to this formula?

  13. hello...........

    how can use product wise and date wise formula in excel...
    as a example..........
    1st march to 15th march my cell phone price 1550/-
    then price increase product value 16march- 31st march - 1575/-
    so suggest me ???
    how to apply condition in excel??????

    Thanking you
    Amit Gaurh

  14. Hello,
    I have a spread sheet with a Header in D1 (Issue date). I am trying to get result in Column F (Review) of "Not Due" if the date is less than 640 days from issue, "Due" if the date is between 641 to 720 days from issue, and finally "Over Due" if it is greater than 721 days from issue. I have been trying the IF function and can only seem to get 2 returns but not the third. Thanking you in advance.
    David.

    • I think I've got it;
      =IF(OR(D2=""),"",IF(D2>=TODAY()-641,"Not Due",IF(D2>=TODAY()-721,"Needs Review","Over Due")))
      I have then applied Conditional formatting so that Not Due = Green, Needs Review = Yellow, and Over Due = Red
      Seems to work Ok.

  15. a
    r1 12,00
    r2 34,00
    r3 78,00

    if the latter is my workbook is it correct to type:
    =IF(30>A1>10;1;IF(70>A1>30;2;IF(A1>70;3))),
    in order to receive the number 1 for the specific condition described or the numbers 2 or for the other conditions described accordingly?
    I think the formula is right but excel unfortunatelly gives results of 1 only (cannot calculate 2 or 3).
    to specify, this is the worksheet after the formulas copied to the b column:

    a b
    r1 12,00 1 ok formula is:=IF(30>A1>10;1;IF(70>A1>30;2;IF(A1>70;3)))
    r2 34,00 1 ??? formula is:=IF(30>A2>10;1;IF(70>A2>30;2;IF(A2>70;3)))
    r3 78,00 1 ??? formula is:=IF(30>A3>10;1;IF(70>A3>30;2;IF(A3>70;3)))

  16. i have 2 sheets one having blanks for all cels in al rows and second sheet having data as 0 and 1 for same cels and rows, i need to merge the data in the third sheet or u can say i need to copy the data in 3rd sheet by Usinf IF formula. Please suggest

  17. Hi Svetlana,

    I am very new to excel and am trying to write an if function that if
    cell D12 = OH multiple cell H38 by 8.25% if
    cell D12 = MI multiple cell H38 by 8.75% otherwise zero

    Thank you for your help

    • Hello Mary,

      Here you go:

      =IF(D12="OH", H38*8.25%, IF(D12="MI", H38*8.75%, 0))

  18. I want to add If formula to a formula that is calculating dates.
    Current formula in cell: =E2-N2
    Result: 2/12/2015
    I want to add a IF Formula to state= if today (Today() ) or less leave cell blank. If not, keep the date.

  19. Good Afternoon,

    I am trying to sort out how much paid and voluntary work I do for a charity, what I need to know how many hours I have done paid.

    So if it says paid in one cell I need it to add the hours to another cell. Is this doable?

    Thank You

    • Hello Cody,

      You can use a SUMIF formula similar to this:

      =SUMIF(B:B, "paid", A:A )

      Where column C contains hours, and column B - work descriptions like "paid".

  20. Hi,

    I'm trying to figure out a formula, where if A is blank than leave destination cell blank, if A contains a date then destination cell to show the month from that date.
    I came up with the following, which pulls the months through, but doesn't leave the cell blank if A does't have a date.

    =IF(ISBLANK(A),"",MONTH(A:A))

    would really appreciate your help.
    thanks,
    Suzie

    • Hi Suzie,

      Because the IF function works on a cell level, you should specify a cell reference in a formula. For example, enter the following formula in row 1, and then coy it down to other cells in the column:

      =IF(ISBLANK(A1),"",MONTH(A1))

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)