Google Sheets IF function - usage and formula examples

The IF function in Google Sheets is one of the easiest functions to learn, and while this holds true, it is also a very helpful one.

In this tutorial, I invite you to take a closer look at how Google Spreadsheet IF function works and what advantages you will get from using it.

What is the IF function in Google Sheets?

Whenever you use the IF function, you create a decision tree in which certain action follows under one condition, and if that condition is not met – another action follows.

For this purpose, the condition of the function must be in a format of the alternative question with only two possible answers: "yes" and "no".

This is what a decision tree may look like: Decision tree of the alternative question.

So, the IF function allows you to ask a question and indicate two alternative actions depending on the received answer. This question and the alternative actions are known as three arguments of the function.

IF function syntax in Google Sheets

The syntax for the IF function and its arguments are as follows:

=IF(logical_expression, value_if_true, value_if_false)
  • logical_expression – (required) a value or logical expression that is tested to see if it is TRUE or FALSE.
  • value_if_true – (required) the operation that is carried out if the test is TRUE.
  • value_if_false – (optional) the operation that is carried out if the test is FALSE.

Let's explore the arguments of our IF function in more detail.

The first argument represents a logical question. Google Sheets answers this question with either "yes" or "no", i.e. "true" or "false".

How to formulate the question properly, you may wonder? To do that, you can write a logical expression using such helpful symbols (or comparison operators) as "=", ">", "<", ">=", "<=", "<>". Let us try and ask such a question together.

Usage of the IF function

Let's assume that you are working in the company selling chocolate in several consumer regions with many clients.

This is what your sales data may look like in Google Sheets: Sample sales data for Google Sheets.

Imagine that you need to separate sales made in your local regions from those from abroad. To accomplish that, you should add another descriptive field for each sale – a country where the sales took place. Since there is a lot of data, you need this description field to be created automatically for each entry.

And this is when the IF function comes to play. Let's add the "Country" column to the data table. "West" region represents local sales (Our Country), while the rest are the sales from abroad (Rest of the World).

How to write out the function properly?

Place the cursor in F2 to make the cell active and type in the equality sign (=). Google Sheets will immediately understand that you are going to enter a formula. That's why right after you type the letter "i" it will prompt you to choose a function that begins with that same letter. And you should choose "IF". Function prompt in Google Sheets.

After that, all your actions will be accompanied by prompts as well.

For the first argument of the IF function, enter B2="West". As with the other Google Sheets functions, you don't need to enter the address of the cell manually – a mouse click is enough. Then enter comma (,) and specify the second argument.

The second argument is a value that F2 will return if the condition is met. In this case, it will be the text "Our Country".

And again, after the comma, write the value of the 3rd argument. F2 will return this value if the condition is not met: "Rest of the World". Do not forget to finish your formula entry by closing parenthesis ")" and pressing "Enter".

Your entire formula should look like this:

=IF(B2="West","Our Country","Rest of the World")

If everything is correct, F2 will return the text "Our Country": Google Sheets IF function.

Now, all you have to do is to copy this function down column F.

Tip. There's one way to process the entire column with one formula. The ARRAYFORMULA function will help you do that. Using it in the first cell of the column, you can test all cells below against the same condition, and return the corresponding result to each row at the same time:

=ARRAYFORMULA(IF(B2:B69="West","Our Country","Rest of the World")) Process entire ranges using IF + ArrayFormula.

Let's examine the other ways of working with the IF function.

IF function and text values

The usage of the IF function with a text has already been illustrated in the example above.

Note. If the text is being used as the argument, then it must be enclosed in double-quotes.

IF function and numerical values

You can use numbers for the arguments just as you did with the text.

However, what is very important here is that the IF function makes it possible to not only fill cells with certain numbers based on the conditions met but also calculate.

For example, let's say you offer your clients various discounts based on the total value of the purchase. If the total is more than 200, then the client gets a 10% discount.

For that, you need to use column G and name it "Discount". Then enter the IF function in G2, and the second argument will be represented by the formula that calculates the discount:

=IF(E2>200,E2*0.1,0) IF with numbers in Google Sheets.

IF blanks/non-blanks

There are cases when your result depends on whether the cell is empty or not. There are two ways to check that:

  1. Use the ISBLANK function.

    For example, the following formula checks if cells in column E are empty. If so, no discount should be applied, otherwise, it's 5% off:

    =IF(ISBLANK(E2)=TRUE,0,0.05) Check if a cell is blank in Google Sheets.

    Note. If there's a zero-length string in a cell (returned by some formula), the ISBLANK function will result in FALSE.

    Here is another formula to check if E2 is empty:

    =IF(ISBLANK(E2)2<>FALSE,0,0.05)

    You can turn the formula the other way around and see if cells are not blank instead:

    =IF(ISBLANK(E2)=FALSE,0.05,0

    =IF(ISBLANK(E2)<>TRUE,0.05,0)

  2. Use standard comparison operators with a pair of double-quotes:

    Note. This method considers zero-length strings (indicated by double-quotes) as empty cells.

    =IF(E2="",0,0.05) – check if E2 is blank

    =IF(E2<>"",0,0.05) – check if E2 is not empty.

    Tip. In a similar manner, use double-quotes as an argument to return an empty cell by the formula:

    =IF(E2>200,E2*0,"")

IF in combination with other functions

As you have already learned, the text, numbers, and formulas can act as the arguments of the IF function. However, other functions can play that role as well. Let's see how it works.

Google Sheets IF OR

Remember the first way you figured out the country where you sold chocolate? You checked if B2 contained "West".

However, you can build the logic the other way around: list all the possible regions that belong to the "Rest of the World" and check if at least one of them appears in the cell. The OR function in the first argument will help you do that:

=OR(logical_expression1, [logical_expression2, ...])
  • logical_expression1 – (required) the first logical value to check for.
  • logical_expression2 – (optional) the next logical value to check for.
  • and so on.

As you can see, you just enter as many logical expressions as you need to check and the function searches if one of them is true.

To apply this knowledge to the table with sales, mention all the regions that belong to the sales abroad, and the other sales will automatically become local:

=IF(OR(B2="East",B2="South"),"Rest of the World","Our Country") IF with OR in Google Sheets.

Google Sheets IF AND

The AND function is just as simple. The only difference is that it checks if all listed logical expressions are true:

=AND(logical_expression1, [logical_expression2, ...])

E.g. you need to narrow the search to your town and you know that it is currently buying only hazelnuts. So there are two conditions to consider: region – "West" and product – "Chocolate Hazelnut":

=IF(AND(B2="West",C2="Chocolate Hazelnut"),"Our Country","Rest of the World") Google Sheets IF AND formula.

Nested IF formula vs. IFS function for Google Sheets

You can also use the IF function itself as an argument for the bigger IF function.

Let's assume that you have set stricter discount conditions for your clients. If the total purchase is more than 200 units, they get a 10% discount; if the total purchase is between 100 and 199, the discount is 5%. If the total purchase is lower than 100, there is no discount whatsoever.

The following formula shows how the function will look in the cell G2:

=IF(E2>200,E2*0.1,IF(E2>100,E2*0.05,0)) Google Sheets nested IF.

Note that it is another IF function that is used as the second argument. In such cases, the decision tree is as follows: Nested IF decision tree.

Let's make it even more fun and complicate the task. Imagine that you're offering the discounted price to the one region only - "East".

To do that correctly, add the logical expression "AND" to our function. The formula will then look the following way:

=IF(AND(B2="East",E2>200),E2*0.1,IF(AND(B2="East",E2>100),E2*0.05,0)) Using AND in Google Sheets nested IF.

As you can see, the number of discounts has reduced greatly while their amount remains intact.

There's also an easier way to write the above thanks to the IFS function:

=IFS(condition1, value1, [condition2, value2, …])
  • condition1 – (required) is the logical expression you want to test.
  • value1 – (required) is the value to return if the condition1 is true.
  • and then you just list conditions with their values to return if they are true.

Here's how the above formula will look with IFS:

=IFS(AND(B2="East",E2>200),E2*0.1,AND(B2="East",E2>100),E2*0.05) Use IFS instead of nested IF.

Tip. If there's no true condition, the formula will return the #N/A error. To avoid that, wrap your formula with IFERROR:

=IFERROR(IFS(AND(B2="East",E2>200),E2*0.1,AND(B2="East",E2>100),E2*0.05),0) Avoid errors with IFERROR.

SWITCH as an alternative to multiple IFs

There's one more function you may want to consider instead of the nested IF: Google Sheets SWITCH.

It checks if your expression corresponds to a list of cases, one by one. When it does, the function returns a corresponding value.

=SWITCH(expression, case1, value1, [case2, value2, ...], [default])
  • expression is any cell reference, or a range of cells, or even an actual math expression, or even a text that you'd like to equal to your cases (or test against the criteria). Required.
  • case1 is your first criteria to check the expression against. Required.
  • value1 is a record to return if the case1 criterion is the same as your expression. Required.
  • case2, value2 repeat as many times as criteria you have to check and values to return. Optional.
  • default is also completely optional. Use it to see a specific record if none of the cases is met. I'd recommend using it every time to avoid errors when your expression doesn't meet matches among all the cases.

Here are a couple of examples.

To test your cells against a text, use ranges as an expression:

=ARRAYFORMULA(SWITCH(B2:B69,"West","Our Country","Rest of the World")) Use a range as an expression to test against the text.

In this formula, SWITCH checks what record is in every cell in column B. If it's West, the formula says Our Country, otherwise, Rest of the World. ArrayFormula makes it possible to process the entire column at once.

To work with calculations, it's better to use a boolean expression:

=SWITCH(TRUE,$E2>200,$E2*0.1,AND($E2<200,$E2>100),$E2*0.05,0) Use booleans as an expression to test against calculations.

Here SWITCH checks if the result of the equation is TRUE or FALSE. When it's TRUE (like if E2 is really greater than 200), I get a corresponding result. If none of the cases in the list is TRUE (meaning they are FALSE), the formula simply returns 0.

Note. SWITCH doesn't know how to calculate the entire range at once, so no ARRAYFORMULA in this case.

IF statements based on a count

One of the questions we get asked a lot is how to create the IF formula that will return whatever you need if the column contains or doesn't contain a certain record.

For example, check if a customer's name appears more than once in a list (column A) and put the corresponding word (yes/no) into a cell.

A solution is simpler than you may think. You need to introduce the COUNTIF function to your IF:

=IF(COUNTIF($A$2:$A$69,$A2)>1,"yes","no") Use COUNTIF within your IF function.

Make Google Sheets build IF formulas for you – IF Formula Builder add-on

If you're tired of keeping track of all those extra characters and proper syntax in formulas, there's another solution available.

IF Formula Builder add-on for Google Sheets offers a visual way of creating IF statements. The tool will handle syntax, extra functions and all required characters for you.

All you need to do is:

  • fill blanks with your records one by one. No special treatment for dates, time, etc. Enter them as you always do and the add-on will recognize the data type.
  • select required comparison operators from the suggested drop-down lists.
  • if needed, add multiple logical expressions in a click: IF OR, IF AND, ELSE IF, THEN IF.
IF Formula Builder add-on for Google Sheets.

As you can see, each logical expression takes its own line. The same goes for true/false outcomes. This reduces the number of possible confusion over the formula drastically.

As you fill everything out, the formula for use will grow in the preview area at the top of the window. To its left, you can select a cell in your sheet where you'd like to have the formula.

When you're ready, paste the formula into the cell of interest by clicking the Insert formula button at the bottom.

Please visit the online tutorial for IF Formula Builder to see all options described in detail.

I hope that there's no room for any doubt now that the IF function, though a very simple one at first glance, opens the door to many options for data processing in Google Sheets. But if you still have questions, feel free to ask them in the comments section down below – we'll be happy to help!

You may also be interested in

Table of contents

607 comments

  1. I created an order form for my craft shows and want the prices to populate when i select each item. I figure its an If:Then type of situation but Its been a long time since I've worked on things like this and could use some guidance

    Column B= Item Description
    Column D= Price

    I made a drop down list for column B to show all the items I currently have in stock. I also have a drop down list in Column D and can manually click on each price. I would love to figure out the proper way to bypass this.

    Example: Items- lollipop and chocolate are $1 each. bubbles, reindeer food, lip balm, and hand sanitizer are $3 each.

    Do I need to say something like If B=lollipop or chocolate then D=$1???

  2. How do i make the cell that has the formula in it blank until it populates? at the moment it has FALSE until the other cell is written in ?

  3. I would like to total the prices (Column D) of rows assigned in Column G. I have Data Validation to make a dropdown of values "1-4" (column G). I want to sum the values of all group 1 column D's, all group 2 column D's, etc to another cell.

  4. Could you please help me with a formula,
    IF the cell is EE then the number is 3, if the cell is ME then the number is 2, if the cell is NW , then the number is 1.

  5. My business focuses on retail, contractor, wholesale sales, but also includes stock. We do batch ordering and a majority of what we order is already pre purchased. I am trying to separate in one column a letter for each: R, C, W are what we are using as our definers. We want a count from each grouping, and also a percentage. Please help....

  6. If I want to past a formula into consecutive vertical cells but want to keep ONE of the sections of the formula the same, is this possible? When I paste it, the L30 goes to L31 then to L32, etc., and the D1 goes to D2 to D3, etc. I'm wanting the L to stay at 30 and the rest to move with each line.

    e.g., If I paste =IF(L30>=12.5,D1*25%,D1*20%) in A1, and =IF(L31>=12.5,D2*25%,D2*20%) in A2, and =IF(L32>=12.5,D3*25%,D3*20%), etc., etc.

  7. Hello Natalia, I'm need to have multiple IFS and am having trouble with the formula. I need a cell to populate a dollar amount based on a percentage range in another cell. If the percentage is between 11 - 11.99 = $125, 12 - 12.99 = $250, 13 - 13.99 = $375, 14 - 14.99 = $500, 15 or more = $750. How can I write this formula?

    Thanks

    • Hello Kevin,

      When it comes to IFS, you simply need to alternate your criteria with its result. The example is illustrated here.

      Assuming the percentage starts in A2, here's how the formula should look like:
      =IFS(AND(A2>=11,A2<=11.99),125,AND(A2>=12,A2<=12.99),250,AND...,etc,etc)

      • PERFECT! Thank you!!!

  8. I'm trying to black out cells if the cell prior has N/A from a drop down list. This would also need applied to the entire column.
    Thank you in advance!

    • Hi Kim,

      I'm sorry but your task is not clear.
      For us to be able to help you, please share a small sample spreadsheet with us (support@apps4gs.com) and include two tabs there: 1 - your source data, 2 - the result you need to get.
      Note. We keep that Google account for file sharing only, please do not email there. Once you share the file, just confirm by replying here. Thank you.

    • Hello William,

      Though your formula works on my side, I'd adjusted it a bit:
      =ARRAYFORMULA(IF($J4:$J="name",$H4:$H*0.85,IF($J4:$J="","",0)))

      ArrayFormula auto-populates the entire column with the formula while the second IF returns an empty cell for those rows where column H is not yet filled with data.

      I tried to look into your file, but I can't access it. If you still need my assistance with the formula, please share an editable copy of your spreadsheet with us directly: press the Share button at the upper right corner of your spreadsheet and enter support@apps4gs.com.
      Note. We keep that Google account for file sharing only and don't monitor its Inbox. Please do not email there. Once you share the file, just confirm by replying here. Thank you.

  10. I'm trying to make a formula but I can't seem to find the answer to what I try to achieve.
    What i'm trying is to automatically subtract a percentage on an array when the cell next to it contains a name.
    =IFERROR(IF($J4:$J = "name", $H4:$H*0.85, $H4:$H*0))
    So if a cell in array J contains a "name, the cell left of where the name is substracts 15% That my formula is wrong, is for sure! But where? Thank you in advanced.

  11. Hi,
    figured it out finally!
    =IF(O$5>=$H6,if(O$5<=$I6,$D6,""),"")
    Patience and time solves everything!

  12. Hi,
    This is for a construction project...looking to put how many people will be on a job for each day. Using Google sheets....
    I have the dates in the main cell as follows:
    P5 is the date in question 5/26/2020
    H6 is the start date 5/26/2020
    I6 is the end date of the project. 11/9/2020
    once i run this formula i can make all cells (for this job) a specific color Perfect, and starts on 5/26/2020 stops on 11/9/2020.... :)
    =AND(O$5>=$H6,O$5=$H6,P$5<=$I6,D6*1,"")
    this does give a blank for the false but how do i get the true statement to read the D6 cell?
    Is there a way to get this number into each cell for the job by not typing it in. Seem so simple yet i am at a loss.
    any help would greatly appreciated
    Thank you

  13. Hi,
    I was wondering if I could receive some help with a formula. I'm trying to figure out how to create a scenario where I can view the commission rate (it differs by company) by company?
    It would be such that column B (where the companies are) would dictate the percentage of commission that's taken, and the percentage is taken from the sum of columns K-M. I want to create a commissions column in column N, and would like for the formula to run the length of the column.
    The % taken is such that Company B has 33% taken, Company IT, S-Corp, and AA has 28% taken, and every other company has 25% taken. I've linked the sheet below for easier viewing:
    https://drive.google.com/file/d/1SZ3U1SXiorYnsTt9566ymPWQDX734CY_/view?usp=sharing
    Thank you!

    • Hi Amanda,

      Thank you for the description and the file.

      To calculate the commission rate by company, use this formula in B7 and copy it down the column:
      =IF(B7="","",IF(B7="B",33%,IF(OR(B7="IT",B7="S-Corp",B7="AA"),28%,25%)))

      To deduct the percentage from the total of columns K-M at the same time, here's another formula:
      =IF(B7="","",IF(B7="B",SUM(K7:M7)-33%,IF(OR(B7="IT",B7="S-Corp",B7="AA"),SUM(K7:M7)-28%,SUM(K7:M7)-25%)))

  14. Hello,
    Can you please help?
    I would like a formula to do the following. I have three columns. Column 1 are a list of dates, Column 2 is also a list of dates, Column 3 is a list of number. I want a sum of column 3 for only the following cells. Cell 1 has a value and Cell 2 does not have a Value.

  15. I've used an IF statement to populate a column with a '1' for a true value and a '0' for a false value. In another cell, I want to sum all of the '1' values but the sum formula isn't picking them up. Is it possible to sum up all of the 1 values returned from all of my IF statements?

      • Hi Natalia,
        I managed to resolve myself thanks. The problem was I has quotation marks around the true and false values which was stopping them displaying as values that could be summed.
        My original statement was =IF("B3=Test","1","0")
        And changing it to =IF("B3=Test",1,0) has fixed it.

        • Hi Harry,
          Thank you for the update. Good to know you managed to fix the formula!
          Double quotes are used for text strings. When used with numbers, they turn numerics into the text and prevent them from being calculated.

  16. Hi
    I am trying to pick shipments from a list whch has columns with several information. I try to fix a correct formula which gives me the result 1 or 0, or True or False or a colour or whatsoever.
    Lets say I want the in Cloumn T see the result if either one of the conditions are fullfilled. Aka if one of the conditions is fullfilled should the result be 1/True/Green cell, etc.
    First condition: IF C3<=3,99 and D3<=999
    2nd condition: IF G3="Yes" and E3<=3
    3rd condition: IF C3=6 and D36 and D3>1000 and D3<2500
    I do not know what I am doing wrong, but I don't get it together, and with only 2 conditions (which are probably wrong) I get 1 as a result for a row with "yes" in cloumn G, whereas if the data in the column is "no", but it fullfills i.e. the first condition, the result is instead of 1, true? Appreciate your help so much. Thank you!

    • Hi
      I forgot the conditions in the 2nd condition
      which is if G3 s "yes" and E3<=3 is kind of missing the part, that if E3=1 should D3<=800, but in case E3=2 should D3<=1600 or in case E3<=3 so should D3<=2400
      how is it possible to combine all the conditions in a formula?
      Sorry for the unconvinience.
      Looking forward to your reply
      Kindest regards

      • Hi Fatos,

        I'm sorry but it's hard to get a clear understanding of what you're trying to achieve.
        For me to be able to advise you anything, please consider sharing a small example spreadsheet with us (support@apps4gs.com) with 2 sheets: a copy of your source data and the result you expect to get. Please include the formula that doesn't work as well and shorten the tables to 10-20 rows.
        Note. We keep that account for file sharing only and don't monitor its Inbox. Please do not email there. Once you share the file, just confirm by replying here.

        In the meantime, please look through the last part of the blog post more closely. It describes how to enter multiple conditions to your formula.

        • Hi Natalia

          Thank you sooo much, I will send you an exempel
          Kind regards

        • Hello

          I've shared the file now

          thanks again!

          • Hello Fatos,

            I'm sorry, I can see no files shared by you. Please follow these steps to share the file correctly:

            1. Create an example spreadsheet in Google Sheets. Make sure there are two sheets: 1 - example data with the formula that doesn't work; 2 - the result you expect to get. Please shorten the tables to 10-20 rows.
            2. Press the Share button at the upper right corner of the Google spreadsheet.
            3. Enter support@apps4gs.com there and click Done.

            The file will then appear in the Shared section of our Drive. For more details on sharing the files, please turn to this help page. Thank you.

            • Hi,
              so sorry, I'll try to send it again. Sorry for the unconvenience... In the meantime did I manage to find I formula which appears to work. But I am not sure if that is the best way to do it. I'll try to send it now

              Thanks a lot & sorry again

            • Hi there
              1 - I've shared as requested a simple version of the file. hope it worked this time

              2- does anybody know how I can create an automated list of tabs/sheets in the same worksheet. Its a schoolproject; a (daily) spreadsheet with over 70 tabs/sheets and we need to have a summary-tab (we need to "analyze" data for a period of 120 days, and have no knowledge or info on coding etc)

              All kind of help is greatly appreciated
              Thank you!

              • Hi,

                Thank you again.
                Re my second question; I need to get a list of the tabs in another (summary tab) tab of the same spreadsheet. Like an index, which I want to use to create a table and "extract and summarize" information, so the names of these tabs are going to be the rows in this table. I was not able to find the funtion to use for this

                Kindest regards

              • Hi Fatos,

                I looked into your file. I created an additional column Q, named it Ablebits, pasted the formula there, and copied it down the column. Here it is:
                =IFERROR(IFS(AND(M2<=2,4;K2<1000);1;AND(AND(M2>2,99;M2<=6);K2<=50);2;AND(M2="pall";AND(N2>0;N2<=3);K2/N2<=800);3);0)

                The formula returns 0 instead of the error when there's no match to any of your conditions. Also, the column cells turned green due to the existing conditional formatting, but I'm not going mess with that. Please adjust your conditional formatting accordingly.:) Hope the formula solves the first task for you.

                As for the second one, I appreciate the additional info. But I'm afraid there's no easy way to avoid entering each sheet name manually. I'd advise you to search for a solution here - an overview of Google Apps Script with a lot of helpful content and links: https://developers.google.com/apps-script/overview
                I wish I could help you better.

              • Thank you for all your help !
                Have a great day...
                Fatos

  17. I have a sheet where data copies from a master tab to a slave where I want some information removed or hidden as it will be shared outside our business. What I would like to achieve is IF it reads (in this case) 4S then the information shows on that second tab, and IF it reads anything else, for example CL, RN or EC then it does not automatically show on the second tab. This is all very new to me so would appreciate if you could advise how I go about this...

  18. I am trying to utilize Google Sheets to take a list of email addresses and see if it has ever been seen before.

    Emails are listed in Colum C and my string is:

    =IF(C2="C2;C1000","YES","NO") however it is returning NO no matter if it has been seen before.

  19. Hi, I need help correcting this formula which refers to a VLOOKUP before an IF command with an "and" condition:

    =IF(VLOOKUP(B69,$B$25:$C$43,2,FALSE)10000,C2560000,1800)))

    • Hi Therese,

      I believe, you just miss the comparison before 10000. If you're looking if the match equals to 10000, it should be:
      VLOOKUP(B69,$B$25:$C$43,2,FALSE) = 10000
      Replace the equal sign with whatever comparison character suits your case.
      Also, there are two excess closing brackets at the very end of the formula.

  20. Most helpful and clear explanation on the internet. I seem to have encountered a problem. The cell I'm referencing has drop-down selector. The value of that cell from my view is whatever value has been selected. But the true statement never returns as true but only as false. =IF(E7="Business Analyst", "BA", "Nope") that only ever returns "Nope" despite that Business Analyst is selected and visible in the cell. Will this just not work or is there some other magic?

    • Hello Christopher,

      Thank you for your lovely feedback!
      Please make sure the values in your Data validation are written exactly the same as you put them into your IF formula. I mean you should keep the same text case, spacing, etc. If you're still unable to make it work, please consider sharing a small sample spreadsheet with us (support@apps4gs.com) where the problem occurs. I kindly ask you to shorten the tables to 10-20 rows.

      Note. We keep that Google account for file sharing only, please do not email there. Once you share the file, just confirm by replying here.

      I'll look into it and do my best to help.

Post a comment



Thank you for your comment!
When posting a question, please be very clear and concise. This will help us provide a quick and relevant solution to
your query. We cannot guarantee that we will answer every question, but we'll do our best :)