by The tutorial showcases a few different formulas to perform two dimensional lookup in Excel. Just look through the alternatives and choose your favorite :)
When searching for something in your Excel spreadsheets, most of the time you'd look up vertically in columns or horizontally in rows. But sometimes you need to look across both rows and columns. In other words, you aim to find a value at the intersection of a certain row and column. This is called matrix lookup (aka 2-dimensional or 2-way lookup), and this tutorial shows how to do it in 4 different ways.
Excel INDEX MATCH MATCH formula
The most popular way to do a two-way lookup in Excel is by using INDEX MATCH MATCH. This is a variation of the classic INDEX MATCH formula to which you add one more MATCH function in order to get both the row and column numbers:
As an example, let's make a formula to pull a population of a certain animal in a given year from the table below. For starters, we define all the arguments:
- Data_array - B2:E4 (data cells, not including row and column headers)
- Vlookup_value - H1 (target animal)
- Lookup_column_range - A2:A4 (row headers: animal names) - A3:A4
- Hlookup_value - H2 (target year)
- Lookup_row_range - B1:E1 (column headers: years)
Put all the arguments together and you will get this formula for two-way lookup:
=INDEX(B2:E4, MATCH(H1, A2:A4, 0), MATCH(H2, B1:E1, 0))
If you need to do a two-way lookup with more than two criteria, take a look at this article: INDEX MATCH with multiple criteria in rows and columns.
How this formula works
While it may look a bit complex at first glance, the formula's logic is really straightforward and easy to understand. The INDEX function retrieves a value from the data array based on the row and column numbers, and two MATCH functions supply those numbers:
INDEX(B2:E4, row_num, column_num)
Here, we leverage the ability of MATCH(lookup_value, lookup_array, [match_type]) to return a relative position of lookup_value in lookup_array.
So, to get the row number, we search for the animal of interest (H1) across the row headers (A2:A4):
MATCH(H1, A2:A4, 0)
To get the column number, we search for the target year (H2) across the column headers (B1:E1):
MATCH(H2, B1:E1, 0)
In both cases, we look for exact match by setting the 3rd argument to 0.
In this example, the first MATCH returns 2 because our vlookup value (Polar bear) is found in A3, which is the 2nd cell in A2:A4. The second MATCH returns 3 because the hlookup value (2000) is found in D1, which is the 3rd cell in B1:E1.
Given the above, the formula reduces to:
INDEX(B2:E4, 2, 3)
And return a value at the intersection of the 2nd row and 3rd column in the data array B2:E4, which is a value in the cell D3.
VLOOKUP and MATCH formula for 2-way lookup
Another way to do a two-dimensional lookup in Excel is by using a combination of VLOOKUP and MATCH functions:
For our sample table, the formula takes the following shape:
=VLOOKUP(H1, A2:E4, MATCH(H2, A1:E1, 0), FALSE)
Where:
- Table_array - A2:E4 (data cells including row headers)
- Vlookup_value - H1 (target animal)
- Hlookup_value - H2 (target year)
- Lookup_row_range - A1:E1 (column headers: years)
How this formula works
The core of the formula is the VLOOKUP function configured for exact match (the last argument set to FALSE), which searches for the lookup value (H1) in the first column of the table array (A2:E4) and returns a value from another column in the same row. To determine which column to return a value from, you use the MATCH function that is also configured for exact match (the last argument set to 0):
MATCH(H2, A1:E1, 0)
MATCH searches for the value in H2 across the column headers (A1:E1) and returns the relative position of the found cell. In our case, the target year (2010) is found in E1, which is 5th in the lookup array. So, the number 5 goes to the col_index_num argument of VLOOKUP:
VLOOKUP(H1, A2:E4, 5, FALSE)
VLOOKUP takes it from there, finds an exact match for its lookup value in A2 and returns a value from the 5th column in the same row, which is the cell E2.
Important note! For the formula to work correctly, table_array (A2:E4) of VLOOKUP and lookup_array of MATCH (A1:E1) must have the same number of columns, otherwise the number passed by MATCH to col_index_num will be incorrect (won't correspond to the column's position in table_array).
XLOOKUP function to look in rows and columns
Recently Microsoft has introduced one more function in Excel that is meant to replace all existing lookup functions such as VLOOKUP, HLOOKUP and INDEX MATCH. Among other things, XLOOKUP can look at the intersection of a specific row and column:
For our sample data set, the formula goes as follows:
=XLOOKUP(H1, A2:A4, XLOOKUP(H2, B1:E1, B2:E4))
Note. The XLOOKUP function is only available in Excel for Microsoft 365, Excel 2021, and Excel for the web.
How this formula works
The formula uses the ability of XLOOKUP to return an entire row or column. The inner function searches for the target year in the header row and returns all the values for that year (in this example, for year 1980). Those values go to the return_array argument of the outer XLOOKUP:
XLOOKUP(H1, A2:A4, {22000;25000;700}))
The outer XLOOKUP function searches for the target animal across the column headers and returns the value in the same position from the return_array.
SUMPRODUCT formula for two-way lookup
The SUMPRODUCT function is like a Swiss knife in Excel – it can do so many things beyond its designated purpose, especially when it comes to evaluating multiple criteria.
To look up two criteria, in rows and columns, use this generic formula:
To perform a 2-way lookup in our dataset, the formula goes as follows:
=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2), B2:E4)
The below syntax will work too:
At the heart of the formula, we compare two lookup values against the row and column headers (the target animal in H1 against all animal names in A2:A4 and the target year in H2 against all years in B1:E1): This results in 2 arrays of TRUE and FALSE values, where TRUE's represent matches: The multiplication operation coerces the TRUE and FALSE values into 1's and 0's and produces a two-dimensional array of 4 columns and 3 rows (rows are separated by semicolons and each column of data by a comma): The SUMPRODUCT functions multiplies the elements of the above array by the items of B2:E4 in the same positions: And because multiplying by zero gives zero, only the item corresponding to 1 in the first array survives: Finally, SUMPRODUCT adds up the elements of the resulting array and returns a value of 2000. Note. If your table has more than one row or/and column headers with the same name, the final array will contain more than one number other than zero, and all those numbers will be added up. As the result, you will get a sum of values that meet both criteria. It is what makes the SUMPRODUCT formula different from INDEX MATCH MATCH and VLOOKUP, which return the first found match.=SUMPRODUCT((A2:A4=H1) * (B1:E1=H2) * B2:E4)
How this formula works
(A2:A4=H1) * (B1:E1=H2){FALSE;FALSE;TRUE} * {FALSE,TRUE,FALSE,FALSE}{0,0,0,0;0,0,0,0;0,1,0,0}{0,0,0,0;0,0,0,0;0,1,0,0} * {22000,13800,8500,3500;25000,23000,22000,20000;700,2000,2300,2500}SUMPRODUCT({0,0,0,0;0,0,0,0;0,2000,0,0})
Matrix lookup with named ranges (explicit Intersection)
One more amazingly simple way to do a matrix lookup in Excel is by using named ranges. Here's how:
Part 1: Name columns and rows
The fastest way to name each row and each column in your table is this:
- Select the whole table (A1:E4 in our case).
- On the Formulas tab, in the Defined Names group, click Create from Selection or press the Ctrl + Shift + F3 shortcut.
- In the Create Names from Selection dialog box, select Top row and Left column, and click OK.
This automatically creates names based on the row and column headers. However, there are a couple of caveats:
- If your column and/or rows headers are numbers or contain specific characters that are not allowed in Excel names, the names for such columns and rows won't be created. To see a list of created names, open the Name Manager (Ctrl + F3). If some names are missing, define them manually as explained in How to name a range in Excel.
- If some of your row or column headers contain spaces, the spaces will be replaced with underscores, for example, Polar_bear.
For our sample table, Excel automatically created only the row names. The column names have to be created manually because the column headers are numbers. To overcome this, you can simply preface the numbers with underscores, like _1990.
As the result, we have the following named ranges:
Part 2: Make a matrix lookup formula
To pull a value at the intersection of a given row and column, just type one of the following generic formulas in an empty cell:
Or vice versa:
For example, to get the population of blue whales in 1990, the formula is as simple as:
=Blue_whale _1990
If someone needs more detailed instructions, the following steps will walk you through the process:
- In a cell where you want the result to appear, type the equality sign (=).
- Start typing the name of the target row, say, Blue_whale. After you've typed a couple of characters, Excel will display all existing names that match your input. Double-click the desired name to enter it in your formula:
- After the row name, type a space, which works as the intersection operator in this case.
- Enter the target column name ( _1990 in our case).
- As soon as both the row and column names are entered, Excel will highlight the corresponding row and column in your table, and you press Enter to complete the formula:
Your matrix lookup is done, and the below screenshot shows the result:
That's how to look up in rows and columns in Excel. I thank you for reading and hope to see you on our blog next week!
62 comments
MATCH does not seem to be returning the correct value when set to exact match.
I've been working through the formula with the evaluation tool, and the first part of the MATCH function returns the correct value, but it does not match it correctly to the row on the table. Changing the match type to less than (1) returns a value, but it is not the value less than the one it should search for, and does not change the value returned when changing the input value. Not sure why the exact match (0) parameter is not working.
For clarity, the row I'm searching through just counts up from 1. The value being searched for is 8. MATCH returns the value in column 6 when searching for any value greater than 6 and in the less than mode (1), and doesn't return anything when set to the exact match (0) mode.
Hi! I can't answer your question as I don't have an example of your data and don't know what formula you are using.
You can find detailed instructions here: Excel MATCH function with formula examples.
I have a table that looks very similar to this one used in the example. In my table, Column A is "Pipe Size" measured in inches (in your example, it's "Animal"), Row 1 is "Pipe Length" measured in feet (in your example, it's "Year"), and my table is populated with maximum gas loads that a pipe with the specific dimensions (size and length) can carry, measured in cubit feet per hour (CFH). In my situation, I know what the "Pipe Length" (ft) and the Load (cfh) is, and I'm wanting to match it to a specific size (inches) in Column A so that I can choose the correct pipe size. How would I be able to do that?
FOR EXAMPLE:
_________50_____100_____150___
__1____1,860___1,320___1,070__
__2____3,870___2,740___2,240__
__3____5,860___4,140___3,390__
Hello Jerad!
If I got you right, the formula below will help you with your task:
=INDEX(A2:A5,MATCH(G2,INDEX(B2:D5,,MATCH(G1,B1:D1,0)),0))
G1 = 100
G2 = 2740
The MATCH(G1,B1:D1,0) function determines the number of the required column. The INDEX(B2:D5,,MATCH(G1,B1:D1,0)) function returns all values from this column. Then the second MATCH function searches for the G2 value in this column and returns the corresponding value from column A using the INDEX function.
Hope this is what you need.
That was exactly what I was looking for, thank you!
Now, the next problem I'm running into is that the load isn't always going to be exactly the numbers found in the data range. The way we read the table is we determine the length of our pipe (B1:D1) and then look down the corresponding column to see where the load would fit. For example, I could have a 100 foot pipe length (C3) carrying a 2000 cfh load. I would choose to size the pipe at 2 inches (A4) because 2000 is too large for 1 inch (max of 1,320).
Can I modify the current formula to factor this in? Or is there another formula I can create in a helper table to help me assign the correct cfh (B2:D5) based on the correct column of pipe length (B2:B4 for 50 ft, C2:C5 for 100 ft, or D2:D5 for 150 ft)?
Hi Jerad!
When searching for the desired value in a column, you can use the XMATCH function instead of the MATCH function and the argument [match_mode]=1 - exact match or the next largest value. Try this formula:
=INDEX(A2:A5,XMATCH(G2,INDEX(B2:D5,,MATCH(G1,B1:D1,0)),1))
I hope my advice will help you solve your task.
Qty value
34 8133.52
6 54.78
2 38.14
15 4851.51
14 1927.33
28 1069.49
Above each line qty & value how i matched with below list
ITA 2 26.92
ITA 6 119.58
CHN 6 2158.5
ITA 6 54.78
AUT 1 545.8
DEU 2 275.06
ITA 15 757.05
DEU 1 75.99
AUT 3 2056.32
AUT 2 197.6
ITA 1 52.46
DEU 2 135.7
CHE 2 38.14
Eg: B2 value is 100 A2=20, b2=90, c2=120, d2=80 need c2 for the row reference a2+d2
kindly help to provide the formula
Hi! If you want to select values whose sum equals a certain number, try these instructions: Find all combinations of numbers that equal a given sum in Excel.
Hi,
Need your help.
how to locate the team based on present time in the below table? for example 11.30am, Tue, Team 7 (1 pax)
Time Slot_____________Mon___________Tue____________Wed___________Thu____________Fri
09.00 am - 10.05 am Team 4 (1 pax) Team 5 (1 pax) Team 6 (1 pax) Team 7 (1 pax) Team 8 (1 pax)
10.05 am - 11.10 am Team 5 (1 pax) Team 6 (1 pax) Team 7 (1 pax) Team 8 (1 pax) Team 1 (1 pax)
11.10 am - 12.15 pm Team 6 (1 pax) Team 7 (1 pax) Team 8 (1 pax) Team 1 (1 pax) Team 2 (1 pax)
12.15 pm - 01.20 pm Team 7 (1 pax) Team 8 (1 pax) Team 1 (1 pax) Team 2 (1 pax) Team 3 (1 pax)
01.20 pm - 02.25 pm Team 8 (1 pax) Team 1 (1 pax) Team 2 (1 pax) Team 3 (1 pax) Team 4 (1 pax)
02.25 pm - 03.30 pm Team 1 (1 pax) Team 2 (1 pax) Team 3 (1 pax) Team 4 (1 pax) Team 5 (1 pax)
03.30 pm - 04.35 pm Team 2 (1 pax) Team 3 (1 pax) Team 4 (1 pax) Team 5 (1 pax) Team 6 (1 pax)
04.35 pm - 06.00 pm Team 3 (1 pax) Team 4 (1 pax) Team 5 (1 pax) Team 6 (1 pax) Team 7 (1 pax)
Please advise.
Thank you.
Regards,
Moh SC
Hi! If I understand your task correctly, this article may be helpful: Excel INDEX MATCH MATCH and other formulas for two-way lookup. However, the problem is that, in your data, column A is text, not time.
If you write only the start time in column A (e.g. 09:00, 10:00, 11:00 ....), then you can use the MATCH function with the Match_type = 1 argument.
For example:
=INDEX(B2:E10, MATCH(H1,A2:A10,1), MATCH(H2,B1:E1,0))
where
H1 - time
H2 - day
Hello all: I am stressed out surfing internet for solution but can not get to the point. Question is related to XL formula. I need to make following formula working or any other formula you suggest that can do the job would be appreciated. Following formula works but I need to add condition on it:
1. Current formula: INDIRECT("E"&MATCH(B17,INDEX(G:G,A13):INDEX(G:G,B13),0)) ==> works but value it returns is not from my range specified.
2. I need to add condition e.g. when values in a range: INDEX(G:G,A13):INDEX(G:G,B13) > 0 then do rest of work (other words, only consider value greater than 0 in a range). Then I tried following formula:
=INDIRECT("E"&MATCH(B17,IF((INDIRECT("G"& A13):INDIRECT("G"&B13)>0), (INDIRECT("G"& A13):INDIRECT("G"&B13))),0))
This formula also does not test the condition and gives me result that does not fall into specified range.
I am not expert, just trying to learn and putting together the pieces. Using XL 2003
How to add condition that will work. Please help. Thanks.
Hi! I can't check your formulas as I don't have your data and can't guess what results you want.
Thanks for response. I do see place here to upload the xl file. But will copy & paste data:
Column E: depths with increments by 0.5 e.g. 1.0, 1.5, 2.0 and so on, can to up to 4000 meters.
Columns F, G, H has various types of data that corresponds to depths.
For a certain interval of depths e.g. 1100 to 1190 for this example (but could be any interval within data range).: A15 = 1100, B15= 1190 then
1. First I need find minimum value from Column G with in specified range: which is: 77 ==I am good with this formula
2. then I need to find row number of this value and return relevant cell value from column E which is: E784: 1125.5
but this formula looks in all data and returns me first found number: 77 from column G, E54 = 761.5. (761.5 is not in my specified range but first appearance of number 77 in col G). Please if you can correct this formula or any other version of formula would be appreciated. Again here is formula as specified in first post.
=INDIRECT("E"&MATCH(B17,IF((INDIRECT("G"& A13):INDIRECT("G"&B13)>0), (INDIRECT("G"& A13):INDIRECT("G"&B13))),0))
My data from xl 2007 is:
E: depth, F: data 1, G: data 2, H: data 3
735 -999.25 -999.25 55.90
735.5 -999.25 -999.25 54.50
736 12.6 0 58.51
736.5 11.4 63 55.55
737 11.1 64 53.66
737.5 10.5 57 55.07
738 10.3 57 58.08
738.5 10 63 55.44
739 11.2 66 53.44
739.5 10.5 54 53.74
740 9.5 47 49.30
740.5 8.3 41 55.33
741 7.8 41 55.43
741.5 6.4 41 54.06
742 6 40 49.56
742.5 2.5 40 52.04
743 2.6 43 52.05
743.5 1.7 39 52.90
Unfortunately, your question is not very clear. Try to explain on a SMALL set of data what you want to do and what result you want to get. You don't need to write a huge number of unnecessary numbers here, as this blog is used by other people as well.
Column E: depths with increments by 0.5
Columns G has relevant data.
I need to search minimum value (if value greater than zero) from Col: G, from depth range/Col: E; 735 to 740 (A15 = 735, B15= 740). Min value is: 47 from Col: G & then find relevant depth from Col: E, which is: 740. Following formula works good.
=INDIRECT("E"&MATCH(B17,IF((INDIRECT("G"& A13):INDIRECT("G"&B13)>0), (INDIRECT("G"& A13):INDIRECT("G"&B13))),0))
But if I change the search range e.g. Col: E; 740 to 745 (A15 = 740, B15= 745) then my formula fails and gives me wrong result. Resulting minimum value is: 39 and relevant value from Col: E should be: 743.5.
Here my formula fails and gives me wrong answer: 739. I do not know what is wrong with formula changing search range gives me wrong answer. Please let me know if question is still not clear. Here is sample data.
Col: E=Depth Col: G = values
735 -999.25
735.5 -999.25
736 0
736.5 63
737 64
737.5 57
738 57
738.5 63
739 66
739.5 54
740 47
740.5 41
741 41
741.5 41
742 40
742.5 40
743 43
743.5 39
744 53
744.5 58
745 63
Hi! If I understand your task correctly, try the following formulas:
=INDEX(E1:E30,MATCH(MINIFS(G1:G30,E1:E30,">="&A15,E1:E30,"<="&B15), (E1:E30>=$A$15)*(E1:E30<=$B$15)*G1:G30, 0))
or
=INDEX(E1:E30,MATCH(MIN(IF((E1:E30>=$A$15) * (E1:E30<=$B$15)*G1:G30>0,(E1:E30>=$A$15) * (E1:E30<=$B$15)*G1:G30," ")), (E1:E30>=$A$15)*(E1:E30<=$B$15)*G1:G30,0))