by The tutorial shows how to separate first and last name in Excel with formulas or Text to Columns, and how to quickly split a column of names in various formats to first, last and middle name, salutations and suffixes.
It is a very common situation in Excel that your worksheet contains a column of full names, and you want to split first and last name into separate columns. The task can be accomplished in a few different ways - by using the Text to Columns feature, formulas, and Split Names tool. Below you will find full details on each technique.
How to split names in Excel with Text to Columns
In situations when you have a column of names of the same pattern, for example only first and last name, or first, middle and last name, the easiest way to split names into separate columns is this:
- Select the column of full names that you'd like to separate.
- Head to the Data tab > Data Tools group and click Text to Columns.
- On the first step of the Convert Text to Columns Wizard, select the Delimited option and click Next.
- On the next step, select one or more delimiters and click Next.
In our case, different parts of names are separated with spaces, so we choose this delimiter. The Data preview section shows that all of our names are parsed just fine.
Tip. If you are dealing with names separated with a comma and space like Anderson, Ronnie, then check the Comma and Space boxes under Delimiters, and select the Treat consecutive delimiters as one checkbox (usually selected by default).
- On the last step, you select the data format and destination, and click Finish.
The default General format works nice in most cases. As the Destination, specify the topmost cell in the column where you want to output the results (please keep in mind that this will overwrite any existing data, so be sure to choose an empty column).
Done! The first, middle, and last name are divided into separate columns:
Separate first and last name in Excel with formulas
As you have just seen, the Text to Columns feature is quick and easy. However, if you plan to make any changes to the original names and are looking for a dynamic solution that will update automatically, you'd better divide names with formulas.
How to split first and last name from full name with space
These formulas cover the most typical scenario when you have the first name and last name in one column separated by a single space character.
Formula to get first name
The first name can be easily extracted with this generic formula:
You use the SEARCH or FIND function to get the position of the space character (" ") in a cell, from which you subtract 1 to exclude the space itself. This number is supplied to the LEFT function as the number of characters to be extracted, starting on the left side of the string.
Formula to get last name
The generic formula to extract a surname is this:
In this formula, you also use the SEARCH function to find the position of the space char, subtract that number from the total length of the string (returned by LEN), and get the RIGHT function to extract that many characters from the right side of the string.
With the full name in cell A2, the formulas go as follows:
Get the first name:
=LEFT(A2,SEARCH(" ",A2)-1)
Get the last name:
=RIGHT(A2,LEN(A2)-SEARCH(" ",A2,1))
You enter the formulas in cells B2 and C2, respectively, and drag the fill handle to copy the formulas down the columns. The result will look something similar to this:
If some of the original names contain a middle name or middle initial, you'd need a bit more tricky formula to extract the last name:
=RIGHT(A2, LEN(A2) - SEARCH("#", SUBSTITUTE(A2," ", "#", LEN(A2) - LEN(SUBSTITUTE(A2, " ", "")))))
Here is a high-level explanation of the formula's logic: you replace the last space in the name with a hash sign (#) or any other character that do not appear in any name and work out the position of that char. After that, you subtract the above number from the total string length to get the length of the last name, and have the RIGHT function extract that many characters.
So, here's how you can separate the first name and surname in Excel when some of the original names include a middle name:
How to separate first and last name from name with comma
If you have a column of names in the Last name, First name format, you can have them split into separate columns by using the following formulas.
Formula to extract first name
Like in the above example, you use the SEARCH function to determine the position of a space character, and then subtract it from the total string length to get the length of the first name. This number goes directly to the num_chars argument of the RIGHT function indicating how many characters to extract from the end of the string.
Formula to extract last name
To get a surname, you use the LEFT SEARCH combination discussed in the previous example with the difference that you subtract 2 instead of 1 to account for two extra characters, a comma and a space.
With the full name in cell A2, the formulas take the following shape:
Get the first name:
=RIGHT(A2, LEN(A2) - SEARCH(" ", A2))
Get the last name:
=LEFT(A2, SEARCH(" ", A2) - 2)
The below screenshot shows the results:
How to split full name to first, last, and middle name
Splitting names that include a middle name or middle initial requires slightly different approaches, depending on the name format.
If your names are in the First name Middle name Last name format, the below formulas will work a treat:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Full name | First name | Middle Name | Last name |
| 2 | FirstName MiddleName LastName | =LEFT(A2,SEARCH(" ", A2)-1) |
=MID(A2, SEARCH(" ", A2) + 1, SEARCH(" ", A2, SEARCH(" ", A2)+1) - SEARCH(" ", A2)-1) |
=RIGHT(A2,LEN(A2) - SEARCH(" ", A2, SEARCH(" ", A2,1)+1)) |
| Result: | David Mark White | David | Mark | White |
To get the first name, you use the already familiar LEFT SEARCH formula.
To get the last name, determine the position of the 2nd space by using nested SEARCH functions, subtract the position from the total string length, and get the length of the last name as the result. Then, you supply the above number to the RIGHT function instructing it to pull that number of characters from the end of the string.
To extract the middle name, you need to know the position of both spaces in the name. To determine the position of the first space, use a simple SEARCH(" ",A2) function, to which you add 1 to start the extraction with the next character. This number goes to the start_num argument of the MID function. To work out the length of the middle name, you subtract the position of the 1st space from the position of the 2nd space, subtract 1 from the result to get rid of a trailing space, and put this number in the num_chars argument of MID, telling it how many characters to extract.
And here are the formulas to separate names of the Last name, First name Middle name type:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Full name | First name | Middle name | Last Name |
| 2 | LastName, FirstName MiddleName | =MID(A2, SEARCH(" ",A2) + 1, SEARCH(" ", A2, SEARCH(" ", A2) + 1) - SEARCH(" ", A2) -1) |
=RIGHT(A2, LEN(A2) - SEARCH(" ", A2, SEARCH(" ", A2, 1)+1)) |
=LEFT(A2, SEARCH(" ",A2,1)-2) |
| Result: | White, David Mark | David | Mark | White |
A similar approach can be used to split names with suffixes:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Full name | First name | Last name | Suffix |
| 2 | FirstName LastName, Suffix | =LEFT(A2, SEARCH(" ",A2)-1) |
=MID(A2, SEARCH(" ",A2) + 1, SEARCH(",",A2) - SEARCH(" ",A2)-1) |
=RIGHT(A2, LEN(A2) - SEARCH(" ", A2, SEARCH(" ",A2)+1)) |
| Result: | Robert Furlan, Jr. | Robert | Furlan | Jr. |
That's how you can split names in Excel by using different combinations of functions. To better understand and probably reverse-engineer the formulas, you are welcome to download our sample workbook to Separate Names in Excel.
Tip. In Excel 365, you can make use of the TEXTSPLIT function to separate names by any delimiter that you specify.
Separate name in Excel 2013, 2016 and 2019 with Flash Fill
Everyone knows that Excel's Flash Fill can quickly fill data of a specific pattern. But did you know that it can also split data? Here's how:
- Add a new column next to the column with the original names and type the name part that you want to extract in the first cell (the first name in this example).
- Start typing the first name in the second cell. If Excel senses a pattern (in most cases it does), it will populate the first names in all other cells automatically.
- All you have to do now is to press the Enter key :)
Tip. Usually the Flash Fill feature is enabled by default. If it does not work in your Excel, click the Flash Fill button on the Data tab > Data tools group. If it still doesn't work, then go to File > Options, click Advanced, and make sure the Automatically Flash Fill box is selected under Editing options.
Split Names tool - fastest way to separate names in Excel
Plain or tricky, Text to Columns, Flash Fill and formulas work well only for homogeneous datasets where all names are of the same type. If you are dealing with different name formats, the above methods will mess up your worksheets by putting some name parts in wrong columns or returning errors, for example:
In such situations, you can commit the work to our Split Names tool, which perfectly recognizes multi-part names, over 80 salutations and about 30 different suffixes, and works smoothly on all version of Excel 2016 to Excel 2007.
With our Ultimate Suite installed in your Excel, a column of names in various formats can be split in 2 easy steps:
- Select any cell containing a name you want to separate and click the Split Names icon on the Ablebits Data tab > Text group.
- Select the desired names parts (all of them in our case) at click Split.
Done! Different parts of names are spread out across several columns exactly as they should, and the column headers are added automatically for your convenience. No formulas, no fiddling with commas and spaces, no pain at all.
If you are curious to try the Split Names tool in your own worksheets, feel free to download an evaluation version of the Ultimate Suite for Excel.
Available downloads
Formulas to split names in Excel (.xlsx file)
Ultimate Suite 14-day fully-functional version (.exe file)
93 comments
Thank you. Separating complex names with multiple middle names worked first time for me. Very nice work Svetlana. We stand with Ukraine.
How do I separate full name in one column that has two name names, 3 name names and 3 names with suffix?
Hi!
To split first, last and middle names, you can use the formulas provided in the article above. To split four or more words into cells, use Split Names tool, Split Text tool or methods described in this article: How to split cells in Excel: Text to Columns, Flash Fill and formulas.
Split Names and Split text tool is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
THANKS FOR THE TIPS
Hi
How can I separate first name and last name for this style in a row [all are in a row] with formula:
Hamed, Karimi; Hiva, Navai; Karim, Sodavi
Thank you
Hi!
First, split text into 3 cells by the separator ";". Then split each of these cells by the delimiter ",". All the necessary information is in the article above.
Thank you - amazing! Worked fabulously!
hello may i ask how will i separate this name Simon, Athena Jhane G. into 3 columns Last name, FIrst Name, Middle Initial. i am having a hard time separating with person who has 2 first name. Thank you.
Hello!
Your problem is easily solved with the Split Names tool. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
Thanks so much for your help!
How to saperate each other Emloyee ID and name from one column?
For example,
A1.
Employee ID Name
100312-Mark-Brown
I hope you understand my questions
Hi!
Have you tried using the formulas in this article?
Try the formula
LEFT(cell, SEARCH("-", cell) - 1)
MID(cell, SEARCH("-", cell) + 1, 50)
Pay attention to this article: How to split text string in Excel by comma, space, character or mask
How about when there is mixed some name who don't have mid name and last name.
Hello!
If you did not find the answer to your question in the article How to split text string in Excel, then give an example of the text and write what you want to extract from it.
How to separate first middle and last name
Raju Kumar j
Srinivas T
Ramesh
Harish Singh Yadav
Please re-check the article above since it covers your case.
Awesome. But how can we delete the first column which includes the First Name and Last name? Because I only wanna see the separated columns?
Hi!
To delete a column, select it, then right-click - delete.
I like the presentation and descriptions.
keep it up
This is amazingly excellent...
I have one more question though: How do you separate an entry name with: First Name, Middle Name, Last Name, & Name Extension;; like >> DAVID DUVALL SMITH JR...?
Thank you
Hi!
Use Split Names tool. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
How can i find i replace kumar
Awesome! Really helped man!!
Is it possible to create a cell that re-formats the name into an email address?
For example, if I have a cell that contains Firstname Lastname, and I want the cell next to it to say Firstname.Lastname@company.com
Hello!
Use the HYPERLINK function:
=HYPERLINK(SUBSTITUTE(A1," ",".")&"@company.com")
Thanks am very grateful the solution you provide works
God bless you richely
How i can give space between first and last name in excel name shown in my excel are like ARMANDOPOMAR.
originally Name is ARMANDO POMAR. please help
Hi,
On what basis do you want to separate first name and last name?
How do I handle a last name such as St. Clair? It is creating an extra column and won't go into the Last Name Column only?
Hello!
First you need to strip the last name with prefix. When doing this, you use a space as a separator. Then separate the prefix from this result in a new column, using dot as a separator.
We have a ready-made solution for your task. I'd recommend you to have a look at our Ablebits Data — Split Names. It is available as a part of our Ultimate Suite for Excel that you can install in a trial mode and check how it works for free.
I hope this will help, otherwise please do not hesitate to contact me anytime.
Hello, In the following example I have lists of many names taking 3 rows each ("C" is in row 1, "C" in row 2, "Kolias" in row 3. Rows 1-2-3 are merged on either side of the name. I would like result to be Cee Kolias in 1 merged cell to match the data on either side. Thank-you!
C
Cee
Kolias
Hello!
To combine the values of three cells, you can use a simple formula
=A1&" "&A2&" "&A3
However, I don't quite understand how you can get "Cee Kolias" from C, C, Kolias.
Please describe your problem in more detail.
What if in once cell there are multiple names? The sample is in once cell, I have 10 names of people? Thank you in advance!
Hello!
You did not provide an example of your data, but I think you might find this article helpful - Extract Nth word from text string
If there is anything else I can help you with, please let me know.
AshishMishra Who to divided Frist name or last name